how to combine vlookup and conditional formating

[Akir4]

Greetings everyone.
anyone can teach me how to combine Vlookup/hlookup with conditional formating?
i have a list of name with a fee limit for everyone.
each week everyone will spend some money. if the amount spend exceed the limit. i need the cell beside the name become red like example that i provide, and vice versa. if it is below limit, i need it to become green.
Note, the fee for week 1, 2, 3, and 4 will be input manually. after the admin input the amount, i want the rules to kick in.
please do inform me, if my explanation are not enough.
hope anyone can tell me step by step.

thank you.

[AliGW]

Two CF rules for I5.

Green:

=AND(I5<>"",I5<=VLOOKUP(H5,C$5:D$23,2,0))

Red:

=AND(I5<>"",I5>VLOOKUP(H5,C$5:D$23,2,0))

Both apply to: =$I$5:$I$23

[etaf]

you could use

=COUNTIFS($C$5:$C$23,H5,$D$5:$D$23,">="&I5)

and in conditional formatting
2 rules
1 for red
=COUNTIFS($C$5:$C$23,H5,$D$5:$D$23,">="&I5)=0

1 for green
=AND(I5<>"",COUNTIFS($C$5:$C$23,H5,$D$5:$D$23,">="&I5)=1)

OR you could colour all the cells Green , and then just use the red rule

for 2007, 2010 , 2013 , 2016 , 2019 or 365 Subscription excel version
Conditional Formatting

Highlight applicable range >>
I5:I23 - Change, reduce or extend the rows to meet your data range of rows

Home Tab >> Styles >> Conditional Formatting
New Rule >> Use a formula to determine which cells to format
Edit the Rule Description: Format values where this formula is true:
=AND(I5<>"", COUNTIFS($C$5:$C$23,H5,$D$5:$D$23,">="&I5)=0)

Format [Number, Font, Border, Fill] fill red
choose the format you would like to apply when the condition is true
OK >> OK

Then repeat for green
=AND(I5<>"",COUNTIFS($C$5:$C$23,H5,$D$5:$D$23,">="&I5)=1)

Now you can also setup the rules in
L, O & R