Print multiple worksheets - each worksheet to a separate pdf

These solutions are attainable, but it would help us to help you if you could share an example workbook, as per the yellow banner above. Maybe you can share a workbook with 3 sheets?

Thanks.

I attached a small file to the original post.

Ron

I have found this VBA code that theoretically does exactly what I want, but i get a file error 11 and division by 0 error. Any ideas?


Sub SaveAsPDF()
Dim CurWorksheet As Worksheet
For Each CurWorksheet In ActiveWorkbook.Worksheets
CurWorksheet.ExportAsFixedFormat Type:=xlTypePDF, _
Filename:=Application.ActiveWorkbook.Path & “\” & CurWorksheet.Name, _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=False
Next CurWorksheet
End Sub

Try

Sub SaveAsPDF()
Dim CurWorksheet As Worksheet
For Each CurWorksheet In ActiveWorkbook.Worksheets
CurWorksheet.ExportAsFixedFormat Type:=xlTypePDF, _
Filename:=Application.ActiveWorkbook.Path & "\" & CurWorksheet.Name & ".pdf", _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=False
Next CurWorksheet
End Sub

Still working on the sum of each page

That works beautifully. Thank you VERY much!

Ron

To add the sum

Sub SaveAsPDF()
Dim lrs As Long
Dim CurWorksheet As Worksheet
For Each CurWorksheet In ActiveWorkbook.Worksheets
With CurWorksheet
    lrs = .Cells(Rows.Count, 3).End(xlUp).Row
    .Range("K" & lrs + 2).Value = WorksheetFunction.Sum(.Range("K3:K" & lrs))
    .Range("M" & lrs + 2).Value = WorksheetFunction.Sum(.Range("M3:M" & lrs))
    .Range("O" & lrs + 2).Value = WorksheetFunction.Sum(.Range("O3:O" & lrs))
End With
CurWorksheet.ExportAsFixedFormat Type:=xlTypePDF, _
Filename:=Application.ActiveWorkbook.Path & "\" & CurWorksheet.Name & ".pdf", _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=False
Next CurWorksheet
End Sub