Delete identical columns from multiple files

I am working with a data set that has hundreds of columns, about 3/4 of which must be deleted. They are irregularly spaced, so I will need to go through manually one time in order to select them and delete them. I estimate it will take about 20 minutes to get through the entire file, which goes down to column RV.

Here's the problem: I have hundreds of these files. ALL of the files have identical columns (containing different data below), and the same columns need to be deleted in each data set. In other words. If AC needs to be deleted in File 1, AC will also need to be deleted in File 2. Is there a way that I can record the columns that must be deleted and then simply copy/paste those columns into a spot that will remove them?

Thank you so much for all your help over the years. You guys are super heroes, seriously.

I've changed this so that you don't have to put in the filename each time.
If you create a test folder with all of your workbooks in, it will run through the lot and delete the columns for you, saving the changed workbook each time.

Sub Button1_Click()

    Dim wb1 As Workbook
    Dim wb2 As Workbook
    Dim sourcesheet As Worksheet
    Dim col As String
    Dim colno As Long
    Dim fullfilename As String
    Dim filename As String
 
    Dim oFSO As Object
    Dim oFolder As Object
    Dim oFile As Object
    Dim i As Long
 
    Set oFSO = CreateObject("Scripting.FileSystemObject")
    Set oFolder = oFSO.GetFolder(Range("B1").Value)
    Set wb1 = ActiveWorkbook
    
    For Each oFile In oFolder.Files
 
        Range("B2").Value = oFile.Name
        Application.ScreenUpdating = False
        
        fullfilename = Range("B1").Value & Range("B2").Value
        filename = Range("B2").Value
    
        Workbooks.Open fullfilename
        Set wb2 = ActiveWorkbook
        Set sourcesheet = wb2.Worksheets("Sheet1")
        
        For i = 1 To 9999
            col = wb1.Worksheets("Sheet1").Range("D" & CStr(i)).Value
            If col = "" Then
                Exit For
            End If
        colno = wb1.Worksheets("Sheet1").Range("E" & CStr(i)).Value - (i - 1)
        sourcesheet.Columns(colno).EntireColumn.Delete
    Next i
    
    Workbooks(filename).Close SaveChanges:=True
    wb1.Activate
    Application.ScreenUpdating = True
    
    Next oFile

End Sub

Croweater, you're my hero. Worked perfectly. Thank you so much.

Happy to have helped.