VBA to Restrict Excel File Copy, Paste, Cut, DragNdrop & Move Sheet

Hello,

I am looking for simple VBA Codes to execute upon opening an excel file to prevent user from following tasks:
- Cut
- Copy
- Paste
- Drag and Drop
- Move/Copy Sheet

The codes should run automatically upon opening the file without any prompt.

Appreciate any help.

Hi

The following code disables Cut, Copy and Paste and *I think* drag and drop but I'm not 100% sure what you mean by that.

This needs to be placed in the "ThisWorkbook Module" and the Workbook will need to be saved and reopened before it takes effect;

Private Sub Workbook_Activate()
Application.CutCopyMode = False
Application.OnKey "^c", ""
Application.CellDragAndDrop = False
End Sub
 
Private Sub Workbook_Deactivate()
Application.CellDragAndDrop = True
Application.OnKey "^c"
Application.CutCopyMode = False
End Sub
 
Private Sub Workbook_WindowActivate(ByVal Wn As Window)
Application.CutCopyMode = False
Application.OnKey "^c", ""
Application.CellDragAndDrop = False
End Sub
 
Private Sub Workbook_WindowDeactivate(ByVal Wn As Window)
Application.CellDragAndDrop = True
Application.OnKey "^c"
Application.CutCopyMode = False
End Sub
 
Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
Application.CutCopyMode = False
End Sub
 
Private Sub Workbook_SheetActivate(ByVal Sh As Object)
Application.OnKey "^c", ""
Application.CellDragAndDrop = False
Application.CutCopyMode = False
End Sub
 
Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
Application.CutCopyMode = False
End Sub

The only way I know to stop people from moving and copying a sheet is to disable the menu completely, this is done by;

Private Sub Workbook_Activate()
Application.CommandBars("Ply").Enabled = False
End Sub

Private Sub Workbook_Deactivate()
Application.CommandBars("Ply").Enabled = True
End Sub

If you want this to work in conjunction with disabling Cut, Copy and Paste then you'll need to replace the two Subs in the first set of code and use them like this;

Private Sub Workbook_Activate()
Application.CommandBars("Ply").Enabled = False
Application.CutCopyMode = False
Application.OnKey "^c", ""
Application.CellDragAndDrop = False
End Sub
 
Private Sub Workbook_Deactivate()
Application.CommandBars("Ply").Enabled = True
Application.CellDragAndDrop = True
Application.OnKey "^c"
Application.CutCopyMode = False
End Sub

Okay let me try this