VBA - changing colour of all graphs

Hello I'm trying to make a loop to edit all the graphs in a workbook. There's a variety of charts with 1, 2, 3 or 4 bars. I want to go through and make all the 1st bars one colour, 2nd bars another etc. I've tried to make a loop (very new to VBA), below, but it fails whenever it gets to a chart with less than 4 bars because it says the 'parameter is not valid'.

How do I edit the below to ignore the FullSeriesCollections is they are not present in the active chart?

Sub ColourChange()

Dim sht As Worksheet
Dim CurrentSheet As Worksheet
Dim cht As ChartObject

Application.ScreenUpdating = False
Application.EnableEvents = False

Set CurrentSheet = ActiveSheet

For Each sht In ActiveWorkbook.Worksheets
For Each cht In sht.ChartObjects
cht.Activate

ActiveChart.FullSeriesCollection(1).Select
With Selection.Format.Fill
.Visible = msoTrue
.ForeColor.RGB = RGB(0, 176, 80)
.Transparency = 0
.Solid
End With
ActiveChart.FullSeriesCollection(2).Select
With Selection.Format.Fill
.Visible = msoTrue
.ForeColor.Brightness = RGB(192, 192, 0)
.Transparency = 0
.Solid
End With
ActiveChart.FullSeriesCollection(3).Select
With Selection.Format.Fill
.Visible = msoTrue
.ForeColor.RGB = RGB(192, 0, 0)
.Transparency = 0
.Solid
End With
ActiveChart.FullSeriesCollection(4).Select
With Selection.Format.Fill
.Visible = msoTrue
.ForeColor.RGB = RGB(192, 0, 192)
.Transparency = 0
.Solid
End With

Next cht
Next sht

CurrentSheet.Activate
Application.EnableEvents = True

End Sub

Thanks

One of the variants, but this is not a modification of your macro ... :

Option Explicit

Sub ColourChange_v1()
Dim chrtnbr%, serColl%, i%, j%
Dim clr1&: clr1 = RGB(0, 176, 80)    ' = 5287936
Dim clr2&: clr2 = RGB(192, 192, 0)   ' = 49344
Dim clr3&: clr3 = RGB(192, 0, 0)     ' = 192
Dim clr4&: clr4 = RGB(192, 0, 192)   ' = 12583104
Dim wsht As Worksheet

    For Each wsht In ThisWorkbook.Worksheets
        With wsht
            chrtnbr = .ChartObjects.Count
            For i = 1 To chrtnbr
                serColl = .ChartObjects(i).Chart.SeriesCollection.Count
                For j = 1 To serColl
                    With .ChartObjects(i).Chart.SeriesCollection(j)
                        With .Interior
                            Select Case j
                                Case 1: .Color = clr1
                                Case 2: .Color = clr2
                                Case 3: .Color = clr3
                                Case 4: .Color = clr4
                                Case Else
                                    MsgBox "Something's wrong with:" & vbCrLf & vbCrLf & _
                                            "Sheet: '" & wsht.Name & "'" & vbCrLf & _
                                            "Chart: '" & wsht.ChartObjects(i).Name & "'" & vbCrLf & _
                                            "Series no: '" & CStr(j) & "'" & vbCrLf & _
                                            "Series name: '" & wsht.ChartObjects(i).Chart.SeriesCollection(j).Name & "'" _
                                            , vbOKOnly, "Info !"
                            End Select
                        End With
                    End With
                Next
            Next
        End With
    Next
End Sub