RMD (Required Minimum Deduction)

I would calculate YoY performance as Jan to Dec, pre-RMD. Then deduct the RMD and use that as the opening value for the next tax year:

	A	B	C	D	E	F	G	H	I	J
1	Age		75		76		77		78
2	Dist Pd		22.9		22		21.2		20.3
3		Tax Year 2016	Balance	Tax Year 2017	Balance	Tax Year 2018	Balance	Tax Year 2019	Balance
4	Opening Value	Interest	$99,500.00	Interest	$96,108.95	Intterest	$94,709.32	Interest	$93,432.19
5	Jan	0.00%	$99,500.00	0.26%	$96,358.83	0.30%	$94,993.45	0.47%	$93,871.32	C5: =C4 * (1 + B5)
6	Feb	0.00%	$99,500.00	0.37%	$96,715.36	0.41%	$95,382.92	0.35%	$94,199.87
7	Mar	0.00%	$99,500.00	0.18%	$96,889.45	0.35%	$95,716.76	0.50%	$94,670.87
8	Apr	0.00%	$99,500.00	0.22%	$97,102.60	0.17%	$95,879.48	0.25%	$94,907.54
9	May	0.00%	$99,500.00	0.44%	$97,529.85	0.36%	$96,224.64	0.27%	$95,163.79
10	Jun	0.00%	$99,500.00	0.10%	$97,627.38	0.14%	$96,359.36	0.48%	$95,620.58
11	Jul	0.00%	$99,500.00	0.21%	$97,832.40	0.15%	$96,503.90	0.20%	$95,811.82
12	Aug	0.00%	$99,500.00	0.38%	$98,204.16	0.37%	$96,860.96	0.16%	$95,965.12
13	Sep	0.00%	$99,500.00	0.41%	$98,606.80	0.24%	$97,093.43	0.29%	$96,243.42
14	Oct	0.00%	$99,500.00	0.11%	$98,715.27	0.50%	$97,578.90	0.39%	$96,618.77
15	Nov	0.50%	$99,997.50	0.17%	$98,883.09	0.33%	$97,900.91	0.11%	$96,725.05
16	Dec	0.50%	$100,497.49	0.34%	$99,219.29	0.16%	$98,057.55	0.39%	$97,102.28
17	RMD		($4,388.54)		($4,509.97)		($4,625.36)		($4,783.36)	C17: =-ROUND(C16/C2, 2)
18	Balance		$96,108.95		$94,709.32		$93,432.19		$92,318.92	C18: =C16 + C17
19
20	YoY		1.002%		3.236%		3.535%		3.928%	C20: =C16 / C4 - 1

Workbook attached before I discard ...

Originally Posted by glaskow4

How can I show that the actual performance of the portfolio is still doing well even though I've taken the RMD and moved it into another taxable investment?

The international-standard calculation used by investment portfolios is the "time-weighted return" (TWR), which is not the same as IRR, despite the terminology.

IMHO, TWR is a misnomer. It is neither weighted, nor is it time-based, notwithstanding some online attempts to rationalize the terminology.

For simplicity, I assume that all of your balances are month-end balances, including "initial balance"

The following demonstrates one way to calculate the TWR.

	A	B	C	D	E	F	G
1	RMD factor	27.4
2	RMD	$3,667.79
3
4		Deposits + Withdrawals	End Bal	Acct Val Chng	TWR Bal	TWR	TWR Bal Chng
5	Initial		$99,500.00		$99,500.00
6	Nov		$99,997.50	$497.50	$99,997.50	0.50%	$497.50
7	Dec		$100,497.49	$499.99	$100,497.49	0.50%	$499.99
8	Jan	-$3,667.79	$97,313.76	-$3,183.73	$100,981.55	0.48%	$484.06
9
10	Total Return	-2.20%
11	Total TWR	1.49%

Formulas:
B2:  =ROUND(C7/B1,2)
B8:  =-B2
B10: =C8/C5 - 1
B11: { =PRODUCT(1+F6:F8) - 1 }
D6:  =C6-C5
E5:  =C5
E6:  =C6-B6
F6:  =E6/E5 - 1
G6:  =E6-E5
Copy D6:G6 into D7:G8

Formulas displayed with curly brackets {...} are array-entered.
Type the formulas without the curly brackets, then press ctrl+shift+Enter instead of just Enter.
Excel displays the curly brackets in the Formula Bar to indicate that the formula is array-entered.

Improvement.... Although the PRODUCT formula is the typical way to demonstrate the Total TWR calculation, in this design, it is equivalent to simply =E8/E5-1.

Note corrections to some of the data. You calculated the RMD correctly (albeit not rounded, as it should be) in your F6, but you copied it incorrectly into your B7.

Column G is not part of the solution. I show it for comparison with your "value increase" data, which is not the "account value change" that we usually see in brokerage account summaries.

PS.... In fact, column D ("account value change") is also not a necessary part of the solution. Again, I show it primarily for comparison with your "value increase" data.