Insert picture from folder in excel cell

I want to insert an image from a specific folder in the excel cell by the name.
Explanation:
In cell A1 I have name of picture I want to insert e.g. 1234
In C:\Users\Me\Desktop I have picture with name 1234

When in A1 I wrote 1234 I want to insert picture from specific folder in cell B1
I should be able to work with different data of cell A1 (range A1:A1000)

Can someone help me.

To actually insert a picture in B1 from a file location, I think, will require VBA to insert the object.

To just open the file for viewing something like this in B1 will take the file name from A1 and open it

Formula:

=HYPERLINK("C:\Users\USERNAME\Pictures\"&A1)

The below code
• loops through each cell in the selected range
• reads the filename from that cell
Note: if the file name does not include the file extension you'll need to append it within the code

• inserts the referenced picture in the cell, at the location you set as FilePath, to the right of the cell:
• resizes the height and width of the picture to the cell's height

Sub InsertPicFromFile()
Dim cCell As Range
Dim FilePath As String

FilePath = "C:\Users\Me\Desktop\"

For Each cCell In Selection
    If cCell.Value <> "" Then
        On Error Resume Next
        ActiveSheet.Shapes.AddPicture _
            Filename:=FilePath & cCell.Value, LinkToFile:=msoFalse, _
            SaveWithDocument:=msoTrue, _
            Left:=cCell.Offset(ColumnOffset:=1).Left, Top:=cCell.Top, _
            Width:=cCell.Height, Height:=cCell.Height
    End If
Next cCell
End Sub

Is that something you can work with?

See the edit I made, below. Change the ".jpg" extension to whatever you need.

Sub InsertPicFromFile()
Dim cCell As Range
Dim FilePath As String

FilePath = "C:\Users\Me\Desktop\"

For Each cCell In Selection
    If cCell.Value <> "" Then
        On Error Resume Next
        ActiveSheet.Shapes.AddPicture _
            Filename:=FilePath & cCell.Value & ".jpg", LinkToFile:=msoFalse, _
            SaveWithDocument:=msoTrue, _
            Left:=cCell.Offset(ColumnOffset:=1).Left, Top:=cCell.Top, _
            Width:=cCell.Height, Height:=cCell.Height
    End If
Next cCell
End Sub

I hope that helps.

Administrative Note:

Welcome to the forum.

We are happy to help, however whilst you feel your request is similar to this thread, experience has shown that things soon get confusing when answers refer to particular cells/ranges/sheets which are unique to your post and not relevant to the original.

Please see Forum Rule #4 about hijacking and start a new thread for your query.

If you are not familiar with how to start a new thread see the FAQ: How to start a new thread