make an automated leaderboard

With your data in columns A and B:
Enter this in E2 and fill down.

Formula:

=LARGE($B$2:$B$6,ROWS($1:1))

Then array-enter this formula in D2 and fill down.

Formula:

=INDEX($A$2:$A$6,SMALL(IF($E2=$B$2:$B$6,ROW($A$2:$A$6)-MIN(ROW($A$2:$A$6))+1),COUNTIF($E$2:$E2,$E2)))

If you aren’t familiar with array-entered formulas array enter means the formula must be committed from edit mode by simultaneously pressing and holding down Ctrl and Shift while hitting Enter.

It does this.

Row\Col	A	B	C	D	E	F
2	David	7		Jeff	10	In E2 :=LARGE($B$2:$B$6,ROWS($1:1))
3	Jeff	10		David	7	In D2 :{=INDEX($A$2:$A$6,SMALL(IF($E2=$B$2:$B$6,ROW($A$2:$A$6)-MIN(ROW($A$2:$A$6))+1),COUNTIF($E$2:$E2,$E2)))}
4	Sylvain	3		Carl	6
5	Paul	1		Sylvain	3
6	Carl	6		Paul	1

Try changing Carl's score ... even making it a duplicate score.

Withdrawn by FR

Column C enter and fill down:

Formula:

=RANK(D2,$D$2:$D$6,1)+COUNTIF($D$2:D2,D2)-1

Column G enter and fill down:

Formula:

=INDEX($A$2:$A$6,MATCH(SMALL($C$2:$C$6,(ROWS($G$3:G3)-1)*1+1),$C$2:$C$6,0))

Column H enter and fill down:

Formula:

=INDEX($D$2:$D$6,MATCH(SMALL($C$2:$C$6,(ROWS($H$3:H3)-1)*1+1),$C$2:$C$6,0))

Column I enter and fill down:

Formula:

=INDEX($B$2:$B$6,MATCH(G3,$A$2:$A$6,0))

Result:

	A	B	C	D	E	F	G	H	I
1	Player	Position	Rank	Score			Leaderboard
2	Carl	Center	2	-5			Player	Score	Position
3	David	Right Helper	3	-4			Jeff	-9	Left Helper
4	Jeff	Left Helper	1	-9			Carl	-5	Center
5	Paul	Left Defense	5	0			David	-4	Right Helper
6	Sylvain	Right Defense	4	-2			Sylvain	-2	Right Defense
7							Paul	0	Left Defense

You have made a spelling mistake in the formula.

You don't say what solution that you are trying and failing with.

What I gave you was done with Excel 2010.