Save n lines in n different files

[JackNext]

Hi guys!

I'm actually stuck in this problem and honestly I don't think that there is any solution within Excel, but let's give a try.

This is my situation: I have an excel file with "n" rows (more than 10000 actually), like this:

333427rc0f8nfw9mcfcw;Hi my name is carl
2423y98h9nvhf92h2f9h;I like to run
yf87wgfhqwe8hf;Dont go alone
dh29h91hd198hdunw9udnq9u;See u soon
...
...
...

What I actually need, is to find a way to save that rows one by one in .txt files: 1 row = file getting a folder with those "n" files. Is there any chance to do not write a dedicated program to do it?

Thank you as always guys!

[ashishmehra2010]

Hi JackNext,

Let's say column A contains name of the file (notepad) i.e. File1,File2 & so on.
Column B contains your text.

The code will pick the text from column B & save it as Notepad with the specified name in column A.

Sub Export_Files()
    Dim sExportFolder, sFN
    Dim rArticleName As Range
    Dim rDisclaimer As Range
    Dim oSh As Worksheet
    Dim oFS As Object
    Dim oTxt As Object

    'sExportFolder = path to the folder you want to export to
    'oSh = The sheet where your data is stored
    sExportFolder = "C:\Users"
    Set oSh = Sheet1

    Set oFS = CreateObject("Scripting.Filesystemobject")

    For Each rArticleName In oSh.UsedRange.Columns("A").Cells
        Set rDisclaimer = rArticleName.Offset(, 1)

        'Add .txt to the article name as a file name
        sFN = rArticleName.Value & ".txt"
        Set oTxt = oFS.OpenTextFile(sExportFolder & "\" & sFN, 2, True)
        oTxt.Write rDisclaimer.Value
        oTxt.Close
    Next
End Sub

Change the name of the path where you want to save the file.

Regards,
AM

[JackNext]

It works :D Ty so much!