2 columns to 1

[dbridges99]

Is there a way to make two columns condense to one easily or a way I can quickly duplicate it the way I was in a new column?

For instance, we have column A and B.

A B
1 5
2 6
3 7
4 8

I want to create a column C that alter between A and B in one column

C
1
5
2
6
3
7
4
8

I have hundreds of rows I need to do this to and I would prefer not reentering all the data.

[mrice]

Paste

=IF(ISODD(CELL("row",C1)),INDIRECT("A" & (CELL("row",C1)+1)/2),INDIRECT("B" & (CELL("row",C1))/2))

into C1 and copy down

[newdoverman]

If your data starts in row 1

=IF(ROW()>COUNT(A:A)+COUNT(B:B),"",IF(MOD(ROW(),2)=1,INDIRECT("A"&ROW()-INT(ROW()/2)),INDIRECT("B"&ROW()-INT(ROW()/2))))

If your data starts in row 2

=IF(MOD(ROW(),2)=0,INDIRECT("A"&ROW()+1-INT((ROW()+1)/2)),INDIRECT("B"&ROW()+1-INT((ROW()+1)/2)))

If your data starts in row 3

=IF(MOD(ROW(),2)=1,INDIRECT("A"&ROW()+2-INT((ROW()+2)/2)),INDIRECT("B"&ROW()+2-INT((ROW()+2)/2)))

Modified and eliminates 0s at end of data. I have used full column references that should be shortened to be suitable for your data:
Start in Row 1:

=IF(ROW()>COUNT(A:B),"",IF(MOD(ROW(),2)=1,INDIRECT("A"&ROW()-INT(ROW()/2)),INDIRECT("B"&ROW()-INT(ROW()/2))))

Start in Row 2:

=IF(ROW()-1>COUNT(A:B),"",IF(MOD(ROW(),2)=0,INDIRECT("A"&ROW()-INT((ROW()-1)/2)),INDIRECT("B"&ROW()-INT((ROW()-1)/2))))

Start in Row 3:

=IF(ROW()-2>COUNT(A:B),"",IF(MOD(ROW(),2)=1,INDIRECT("A"&ROW()-INT((ROW()-2)/2)),INDIRECT("B"&ROW()-INT((ROW()-2)/2))))

Start in Row 4:

=IF(ROW()-3>COUNT(A:B),"",IF(MOD(ROW(),2)=0,INDIRECT("A"&ROW()-INT((ROW()-3)/2)),INDIRECT("B"&ROW()-INT((ROW()-3)/2))))