Radio Buttons Not Grouping

[bobmaucher]

Hi,

I've been struggling with this issue for a few days, and I'm hoping the experts here can solve it for me.

I'm building a spreadsheet that contains 20 - 30 questions about the condition of a home.

For example, "Paint" would be classified as one of the following: "OK", "Needs Touch Up", or "New Paint Job".
Same thing for "Carpet", "Appliances", and so on.

I'm using radio button forms for each option, and using the control group to bunch them separately.

The first three or four work as I would expect.

Below that, the groupings don't seem to serve their purpose. In any of the next 20 questions, the option buttons function as if there is no grouping whatsoever. When in reality, each group is separated by a box. But I can only select one option of all the groups. It should be one PER group.

Does that make sense? Any thoughts? Any other information you'd need to solve this problem?


Thanks very much!!

[tigeravatar]

bobmaucher,

Welcome to the forum!

Does this require radio buttons?
If you're using the sheet directly, i'd suggest using a validation drop down list for each question instead of radio buttons.
If you're using a userform, you can more easily group radio buttons/questions with the Frame control. Each frame would be a question, and then you'd put the desired radio buttons in the frame. (Though I'd still recommend using the sheet directly with data validation drop-down lists)

[bobmaucher]

Thanks, tigeravatar!

Does it require radio buttons? No. But someone will be using this form repeatedly (on an iPad), and I'm looking to minimize the number of times they touch it. It's just in the interest of efficiency. Radio button would require one "click", and validation drop down list would require two. Such a small difference, I know - but I'm just looking to make it as easy to use and efficient as possible. If you think the radio buttons really mess it up, then I'd consider getting rid of them.

I am not using a userform, although I will consider it. Thanks for that suggestion. Best case, I can fix these option buttons. But if not, that's likely the way I'll go.

Attached is a sample of what I'm trying to do. There will be formulas that calculate cost, based on which options are selected.
Property Checklist Template.xlsm


Thanks again!

[tigeravatar]

bobmaucher,

Does it require radio buttons? No. But someone will be using this form repeatedly (on an iPad), and I'm looking to minimize the number of times they touch it. It's just in the interest of efficiency. Radio button would require one "click", and validation drop down list would require two

Since you know they'll be "clicking" instead of using a keyboard, and you only want one click per answer, you can use a selection_change event instead of radio buttons. Attached is a modified version of your workbook that does just that. It will put an X in the selected item. Here is the code it uses:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    
    Dim strResult As String
    
    If Target.Cells.Count > 1 Or Intersect(Target, Me.Range("B6:D20,B24:D54")) Is Nothing Then Exit Sub
    
    Application.EnableEvents = False
    If Target.Value = "X" Then strResult = vbNullString Else strResult = "X"
    Intersect(Target.EntireRow, Columns("B:D")).ClearContents
    Target.Value = strResult
    Application.EnableEvents = True
    
End Sub

[TylerM02]

new to this whole site and figuring out how to attach my document.. Please stay tuned....

[TylerM02]

I am creating a checklist which has multiple plates and items to be considered for each plate. Each item is either “Required” or “N/A” for each plate. I have used the above macro but I can only manipulate the macro to work for one Plate. I would like for each plate used to have its own separate change selection (check box) for each item. What am I doing wrong here?
Please let me know if you need any additional information.

Here we go. Please see attached...

[martindwilson]

yes a sample workbook showing what's not working

[martindwilson]

the group boxes arent around the buttons you think they are, make all the rows bigger say about 2 inches nothing lines up

[TylerM02]

I am creating a checklist which has multiple plates and items to be considered for each plate. Each item is either “Required” or “N/A” for each plate. I have used the above macro but I can only manipulate the macro to work for one Plate. I would like for each plate used to have its own separate change selection (check box) for each item. What am I doing wrong here?
Please let me know if you need any additional information.

[TylerM02]

To expand a little from my post above. I currently have Columns V and W Rows 41-49 and 55-99, as a check box "Selection Change", macro from tigeravatar above. I would like Y:Z, AB:AC, AE:AF, AH:AI, AK:AL and AN:AO to have their own set of check box (selections). I like the selection change as you can only select one or the other and would like to continue that for the additional Plates found in Row 32 (V, Y, AB, AE, AH, AK and AN). I plan on adding in a formula where if any of these plates/items are selected, each topic (found in column AR) must have either "Required" or "N/A" selected. If it makes more sense to structure the spreadsheet differently, I am open to suggestions. I used to be involved in the excel community but I have not used macros/VBAs for about 9 years now and I am a little out of shape.

[tigeravatar]

Hello TylerM02,

Welcome to the forum!
I believe something like this is what you're looking for:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    
    Dim strResult As String
    Dim rngSelected As Range
    
    If Target.Cells.Count > 1 Then Exit Sub
    Set rngSelected = Intersect(Target, Me.Range("Y41:Z49,Y55:Z99," & _
                                                 "AB41:AC49,AB55:AC99," & _
                                                 "AE41:AF49,AE55:AF99," & _
                                                 "AH41:AI49,AH55:AI99," & _
                                                 "AK41:AL49,AK55:AL99," & _
                                                 "AN41:AO49,AN55:AO99"))
    
    If Not rngSelected Is Nothing Then
        Application.EnableEvents = False
        Select Case rngSelected.Column
            Case Columns("Y").Column, Columns("Z").Column:      MarkSelection Range("Y:Z"), rngSelected
            Case Columns("AB").Column, Columns("AC").Column:    MarkSelection Range("AB:AC"), rngSelected
            Case Columns("AE").Column, Columns("AF").Column:    MarkSelection Range("AE:AF"), rngSelected
            Case Columns("AH").Column, Columns("AI").Column:    MarkSelection Range("AH:AI"), rngSelected
            Case Columns("AK").Column, Columns("AL").Column:    MarkSelection Range("AK:AL"), rngSelected
            Case Columns("AN").Column, Columns("AO").Column:    MarkSelection Range("AN:AO"), rngSelected
        End Select
        Application.EnableEvents = True
    End If
    
End Sub

Private Sub MarkSelection(ByVal rngColumns As Range, ByVal rngTarget As Range)
    
    Dim strResult As String
    If rngTarget.Value = "X" Then strResult = vbNullString Else strResult = "X"
    Intersect(rngTarget.EntireRow, rngColumns.EntireColumn).ClearContents
    rngTarget.Value = strResult
    
End Sub

[6StringJazzer]

I am creating a checklist

TylerM02, welcome to the forum, but we do not allow new questions to be posted in a thread. If you have a new question, please start a new thread.

tigeravatar, at the Guru level please help us remind members of the rules.

Because this thread is old I am going to close it.

Unfortunately your post does not comply with Rule 2 of our Forum RULES. Do not post a question in the thread of another member -- start your own thread.

If you feel an existing thread is particularly relevant to your need, provide a link to the other thread in your new thread.

Old threads are often only monitored by the original participants. New threads not only open you up to all possible participants again, they typically get faster response, too.