Formula for finding unique data for lists

Unique or distinct values?

Please find the attached sheet to see if this is what you are trying to achieve.

Try this Array Formula in E2. Since this is an array formula so you need to confirm it with Ctrl+Shift+Enter instead of just Enter. (i.e. after pasting the formula in the formula cell, hold down the Ctrl+Shift and then press Enter)

In E2

=IFERROR(IFERROR(INDEX($A$2:$A$6,SMALL(IF(ISNA(MATCH($A$2:$A$6,$B$2:$B$6,0)),ROW($A$2:$A$6)-ROW($A$2)+1),ROWS(E$2:E2))),INDEX($B$2:$B$6,SMALL(IF(ISNA(MATCH($B$2:$B$6,$A$2:$A$6,0)),ROW($B$2:$B$6)-ROW($B$2)+1),ROWS(E$2:E2)-SUMPRODUCT(--(IF($A$2:$A$6<>$B$2:$B$6,1)))))),"")

and copy down until you get blank cells.

Try this Array Formula. (CSE confirmed)

=IFERROR(IFERROR(INDEX($A$2:$A$6,SMALL(IF(ISNA(MATCH($A$2:$A$6,$B$2:$B$6,0)),ROW($A$2:$A$6)-ROW($A$2)+1),ROWS(E$2:E2))),INDEX($B$2:$B$6,SMALL(IF(ISNA(MATCH($B$2:$B$6,$A$2:$A$6,0)),ROW($B$2:$B$6)-ROW($B$2)+1),ROWS(E$2:E2)-SUMPRODUCT(--(ISNA(MATCH($A$2:$A$6,$B$2:$B$6,0))))))),"")

See the attached sheet in post#10. Where is the column E?

I hope that you have some "serious" computing power because this is going to take a while to process with nearly 800,000 rows.

Here is the ARRAY formula (Enter with Ctrl + Shift + Enter) with the minor corrections for entry into column C

Formula:

=IFERROR(IFERROR(INDEX($A$2:$A$30,SMALL(IF(ISNA(MATCH($A$2:$A$30,$B$2:$B$30,0)),ROW($A$2:$A$30)-ROW($A$2)+1),ROWS(C$2:C2))),INDEX($B$2:$B$30,SMALL(IF(ISNA(MATCH($B$2:$B$30,$A$2:$A$30,0)),ROW($B$2:$B$30)-ROW($B$2)+1),ROWS(C$2:C2)-SUMPRODUCT(--(ISNA(MATCH($A$2:$A$30,$B$2:$B$30,0))))))),"")

There are two issues with the file you attached in the post#13.
1). The formula I suggested is an array formula so you need to confirm it with Ctrl+Shift+Enter not just Enter. (i.e. after pasting the formula in the cell, press F2, hold down the Ctrl+Shift and then press Enter.). When an array formula is entered correctly, you will notice in the formula bar that the formula gets surrounded by the Curly Brackets {}. And if you don't see the curly brackets in the formula bar, repeat the process to enter it correctly by pressing F2 (Function Key) and holding down the Ctrl+Shif together and pressing Enter then.

2). The numbers in column A are numbers stored as Text (not real numbers), while the numbers in col. B are real numbers. You need to take care of this. Here is the modified formula. Notice in the formula I have used $A$2:$A$30*1 rather than $A$2:$A$30 only, because multiplying $A$2:$A$30 by 1 makes $A$2:$A$30 the real numbers.

=IFERROR(IFERROR(INDEX($A$2:$A$30,SMALL(IF(ISNA(MATCH($A$2:$A$30*1,$B$2:$B$30,0)),ROW($A$2:$A$30)-ROW($A$2)+1),ROWS(E$2:E2))),INDEX($B$2:$B$30,SMALL(IF(ISNA(MATCH($B$2:$B$30,$A$2:$A$30*1,0)),ROW($B$2:$B$30)-ROW($B$2)+1),ROWS(E$2:E2)-SUMPRODUCT(--(ISNA(MATCH($A$2:$A$30*1,$B$2:$B$30,0))))))),"")

Is this what you are trying to achieve?

Just for "kicks" I added 2 helper columns and a 3rh column with a non-array formula to find the unique values. Maybe a solution like this could work for you. I don't know what the comparative speed of calculation is.