next higher number row

Try this...

=IFERROR(INDEX(A1:A14,MATCH(B1,A1:A14,0)+1),"")

Ooops!

I just noticed there were duplicate numbers.

Data Range

	A	B
1	3	3.25
2	3.25	3.5
3	3.25
4	3.5
5	4
6	4
7	4
8	4.25
9	4.25
10	4.5
11	4.75
12	4.75
13	4.75
14	5
15	------	------

Try this array formula**:

=IFERROR(1/(1/MIN(IF(A1:A14>B1,A1:A14))),"")

** array formulas need to be entered using the key
combination of CTRL,SHIFT,ENTER (not just ENTER).
Hold down both the CTRL key and the SHIFT key
then hit ENTER.

=IFERROR(1/(1/MIN(IF(A1:A14>B1,A1:A14))),"")

If there are no numbers greater than the lookup value then the MIN function will return 0.

You don't want a result of 0 so I intentionally wrote the formula so that it will cause an error to be generated if there are no numbers greater than the lookup value. But, we then use the IFERROR function to trap that error.

We can say that 1 divided by 1 divided by some number will equal that number UNLESS that number is 0. When the number is 0 the division operations will result in the #DIV/0! error.

For example:

If the result of:

MIN(IF(A1:A14>B1,A1:A14)) = 3.25

Then:

1/(1/MIN(IF(A1:A14>B1,A1:A14))) = 3.25

Then:

=IFERROR(3.25,"") = 3.25

However, if there are no numbers greater than the lookup value the result of:

MIN(IF(A1:A14>B1,A1:A14)) = 0

Then:

1/(1/MIN(IF(A1:A14>B1,A1:A14))) = #DIV/0!

Then:

=IFERROR(#DIV/0!,"") = "" (blank)