Identify changes to text

[ajob]

I have Names in two columns. Column A has the original name and column B has the name after it has been changed. In column C I want the change made to appear.

See attached sample.

[protonLeah]

Option Explicit
Sub comparestrings()
    Dim NameParts   As Variant, _
        Name1       As String, _
        Name2       As Range, _
        Name2List   As Range, _
        Ndx         As Long, _
        Results     As String
        
    With Sheets("sheet1")
        Ndx = .Cells(Rows.Count, 3).End(xlUp).Row
        
        'dimension the block of names in column C
        Set Name2List = .Range("C2").Resize(Ndx - 1)
        
        'Go down the list of changes
        For Each Name2 In Name2List
            Results = ""
            
            'copy old name for testing
            Name1 = Name2.Offset(0, -1).Value
            
            'break-up the new name into separate elements of an array
            NameParts = Split(Name2)
                        
            For Ndx = 0 To UBound(NameParts)
            
                'search the old name for each element of the new name
                If InStr(Name1, NameParts(Ndx)) = 0 Then
                
                    'if the part is not found, add it to the results string
                    Results = Results & NameParts(Ndx) & " "
                End If
            Next Ndx
            
            'write the results to the sheet
            Name2.Offset(0, 1).Value = Results
            Erase NameParts
            
        Next Name2
    End With
        
End Sub

---

How to install your new code

1. Copy the Excel VBA code
2. Select the workbook in which you want to store the Excel VBA code
3. Press Alt+F11 to open the Visual Basic Editor
4. Choose Insert > Module
5. Edit > Paste the macro into the module that appeared
6. Close the VBEditor
7. Save your workbook (Excel 2007+ select a macro-enabled file format, like *.xlsm)

To run the Excel VBA code:

1. Press Alt-F8 to open the macro list
2. Select a macro in the list
3. Click the Run button

[ajob]

Solves my issue. Thanks for the answer its appreciated.