Formula for Calculating Square Footage

[mknewnham]

I've done a little bit of research but am still super puzzled on how this works.

This formula would be save me (& my client) a lot of time.

Example of what I need:

Size of the room (D17): 5'6" x 12'4"
Square Feet (E17) : ??? <--- need formula for this

THANKS!! And laymans terms...im a newbie to excel

[FDibbins]

Hi and welcome to the forum

I will show you 2 ways to do this (well, 1 way really - 1 that breaks each formula down, and 1 way that combines all formulas)

Because you have all the data in 1 cell, we have to break out each part, so that we can build it back up again.

To break out the 1st feet...
=LEFT(A1,FIND("'",A1,1)-1)
this pulls out the 5

to find the 1st inches (this starts getting more complex)...
=MID(A1,FIND("'",A1,1)+1,FIND(CHAR(34),A1,1)-1-FIND("'",A1,1))
This pulls out the 6

For the 2nd feet...
=MID(A1,FIND("x",A1,1)+1,FIND("'",A1,FIND("x",A1,1))-1-FIND("x",A1,1))
This pulls out the 12

for the last inches...
=MID(A1,FIND("'",A1,FIND("x",A1,1))+1,FIND(CHAR(34),A1,FIND("x",A1,1))-1-FIND("'",A1,FIND("x",A1,1)))
This pulls out the 4

OK so now we have the 4 components, we can work out the area.
You can either put each of those into their own cell and then add/multiply them together in a 5th cell (you can hide the 1st 4 columns of this if you want), or you can combine them into 1 bit ugly monster. Combining makes for lecc columns, but the formula becomes really hard to debug or change - so thats your choice. Anyway, here if the big 1...

=(LEFT(A1,FIND("'",A1,1)-1)+(MID(A1,FIND("'",A1,1)+1,FIND(CHAR(34),A1,1)-1-FIND("'",A1,1))/12))*(MID(A1,FIND("x",A1,1)+1,FIND("'",A1,FIND("x",A1,1))-1-FIND("x",A1,1))+(MID(A1,FIND("'",A1,FIND("x",A1,1))+1,FIND(CHAR(34),A1,FIND("x",A1,1))-1-FIND("'",A1,FIND("x",A1,1)))/12))

This takes (5+6/12)*(12+(4/12) to give 67.83333333 squ feet
(whew lol)

[mikeTRON]

haha Nice lol

[FDibbins]

Thanks Mike and thanks for the feedback. That sure was quite a mouthful, I have actually added it to my list of "useful formulas"

[mknewnham]

Holy Cow!! This is definitely more complicated than I realized. But you definitely helped break it down and now I understand how it works. Thank you so so so much for your time

[arlu1201]

Based on your last post in this thread, its apparent that you are satisfied with the solution(s) you've received and have solved your question, but you haven't marked your thread as "SOLVED". I will do it for you this time.

In future, to mark your thread as Solved, you can do the following -
Select Thread Tools-> Mark thread as Solved.

Incase your issue is not solved, you can undo it as follows -
Select Thread Tools-> Mark thread as Unsolved.

Also, since you are relatively new to the forum, i would like to inform you that you can thank those who have helped you by clicking the small star icon located in the lower left corner of the post which helped you. This adds to the reputation of the person who has taken the time to help you.