How to combine multiple rows of duplicate data and one cell of unique data

I have a customer list of over 7000. In columns A-J, lists the customers information and in column K the type of product. There are rows with duplicate customer information (up to 12 rows) because of the different products in the last column.

I would like to have a list that combines the duplicate customer information into a single row and lists the different products in one cell separating each with a comma.

Is there an easy way I can do this? I'm having such a hard time and I also looked in the forum for the equation but was unsuccessful.

I appreciate the help in advance!
Sample-Data.xlsx

Look at the 3rd posting in this thread

http://www.excelforum.com/excel-form...e-results.html

Install the vba UDF and run it. Then do a delete duplicates from the ribbon.

You need a VBA UDF (User Defined Function) to do this.

Are you familiar with using macros?

With your file open...

Press the key combination of Alt+F11 to open the Visual Basic Editor

Goto the menu Insert>Module

Copy the VBA code below and paste it into the window that opens on the right side of the screen

Press the key combination of ALT+Q to close the Visual Basic Editor and return to Excel.

Public Function ConcatAll(ByVal varData As Variant, Optional ByVal sDelimiter As String = vbNullString, Optional ByVal bUnique As Boolean = False) As String
'Created by TigerAvatar at www.excelforum.com, September 2012
'Purpose is to concatenate many strings into a single string
'Can be used with arrays, range objects, and collections
    
    Dim DataIndex As Variant    'Used to loop through arrays, range objects, and collections
    Dim strResult As String     'Used to build the result string
    
    'Test if varData is an Array, Range, or Collection
    If IsArray(varData) _
    Or TypeOf varData Is Range _
    Or TypeOf varData Is Collection Then
        
        'Found to be an, array, range object, or collection
        'Loop through each item in varData
        For Each DataIndex In varData
            'Check if the item isn't empty
            If Len(DataIndex) > 0 Then
                'Found the item isn't empty, check if user specified bUnique as True
                If bUnique = True Then
                    'bUnique is true, check if the item has been included in the result yet
                    If InStr(1, "||" & strResult & "||", "||" & DataIndex & "||", vbTextCompare) = 0 Then
                        'Item has not been included in the result, add item to the result
                        strResult = strResult & "||" & DataIndex
                    End If
                Else
                    'bUnique is not true, add item to the result
                    strResult = strResult & "||" & DataIndex
                End If
            End If
        Next DataIndex
        
        'Correct strResult to remove beginning delimiter and convert "||" to the specified sDelimiter
        strResult = Replace(Mid(strResult, 3), "||", sDelimiter)
        
    Else
        'Found not to be an array, range object, or collection
        'Simply set the result = varData
        strResult = varData
    End If
    
    'Output result
    ConcatAll = strResult
    
End Function

Then, in your file...

Enter this array formula** in cell K18:

=concatall(IF(B$2:B$12=B18,K$2:K$12,""),",")

** array formulas need to be entered using the key
combination of CTRL,SHIFT,ENTER (not just ENTER).
Hold down both the CTRL key and the SHIFT key
then hit ENTER.

Copy down as needed.

P.S.

If you're using Excel 2007 or later you'll have to save the file as a macro enabled file in the *.xlsm file format.

Here's your file with this implemented:

Sample Data(1).xlsm

You're welcome. Thanks for the feedback!