Count unique values in columns based on 2 criteria

Excel 2013
I am trying to calculate the following values. The spreadsheet is attached.

Unique Emails 7 (formula I am using is below)
count of phones without emails (answer is 1)
count of UNIQUE emails without phones answer is 3
count of UNIQUE emails with phones answer is 4



Column A Column B
email@yahoo.com (212) 888-8888
emailg@gmail.com
ddd@gmail
yyyyy@msn.com (203) 555-1212
yyyyy@msn.com (203) 555-1212
(312) 888-2222
gggg@hotmail.com
gggg@hotmail.com (212) 999-7777
oooonooo@mail.com
fffff@right.com (312) 444-2222


=SUM(IF(FREQUENCY(IF(LEN(A6:A15)>0,MATCH(A6:A15,A6:A15,0),""), IF(LEN(A6:A15)>0,MATCH(A6:A15,A6:A15,0),""))>0,1))

based on your sample file - all to be ARRAY-entered, except the one with COUNTIFS:

Unique Emails

=SUM(IF(FREQUENCY(IF(A6:A15<>"", MATCH(A6:A15,A6:A15,0)),ROW(A6:A15)-MIN(ROW(A6:A15))+1),1))

count of phones without emails

=COUNTIFS(B6:B15,"<>",A6:A15,"=")

count of UNIQUE emails without phones

=SUM(IF(FREQUENCY(IF((A6:A15<>"")*(B6:B15=""), MATCH(A6:A15,A6:A15,0)),ROW(A6:A15)-MIN(ROW(A6:A15))+1),1))

count of UNIQUE emails with phones

=SUM(IF(FREQUENCY(IF((A6:A15<>"")*(B6:B15<>""), MATCH(A6:A15,A6:A15,0)),ROW(A6:A15)-MIN(ROW(A6:A15))+1),1))

shy, Im sorry to have to do this, but...
Unfortunately your post does not comply with Rule 2 of our Forum RULES. Do not post a question in the thread of another member -- start your own thread.

If you feel an existing thread is particularly relevant to your need, provide a link to the other thread in your new thread.

Old threads are often only monitored by the original participants. New threads not only open you up to all possible participants again, they typically get faster response, too.