count alphanumeric codes only counting odd numbers not even numbers?

Do the strings ALWAYS start with 2 letters followed by a 3 digit number?

You won't be able to include this in your COUNTIFS formula.

You might be better off extracting the number first and then testing for MOD(number,2)=0.

If this is your data in the range A1:A7...

YP213
YP212
YP213B
YP212B
YP202
YP203
YP203B

Enter this formula in B1 and copy down:

=IF(COUNT(1*RIGHT(A1)),--RIGHT(A1,3),--LEFT(RIGHT(A1,4),3))

Then you can use the range B1:B7 to test for even numbers.

MOD(A1:A7,2)=0

You'll have to use something like this:

=SUMPRODUCT(--(MOD(A1:A1968,2)=0),--(F1:F1968="GLOCK"),--(G1:G1968="SW"))

If you just want the count of even numbers then try this array formula**:

=SUM(IF(MOD(IF(ISNUMBER(1*RIGHT(A1:A7)),--RIGHT(A1:A7,3),--LEFT(RIGHT(A1:A7,4),3)),2)=0,1))

This one will only work in Excel 2007 and later:

Array entered**:

=SUM(--ISEVEN(IF(ISNUMBER(1*RIGHT(A1:A7)),--RIGHT(A1:A7,3),--LEFT(RIGHT(A1:A7,4),3))+0))

** array formulas need to be entered using the key
combination of CTRL,SHIFT,ENTER (not just ENTER).
Hold down both the CTRL key and the SHIFT key
then hit ENTER.

Argh!

I only need to know the odd numbered ones.

I guess I wasn't paying attention. The formulas I posted are based on counting the EVEN numbers, not the odd numbers.

However, the fix is fairly easy.

=SUMPRODUCT(--(MOD(A1:A1968,2)>0),--(F1:F1968="GLOCK"),--(G1:G1968="SW"))

Array formulas**:

=SUM(IF(MOD(IF(ISNUMBER(1*RIGHT(A1:A7)),--RIGHT(A1:A7,3),--LEFT(RIGHT(A1:A7,4),3)),2)>0,1))

=SUM(--ISODD(IF(ISNUMBER(1*RIGHT(A1:A7)),--RIGHT(A1:A7,3),--LEFT(RIGHT(A1:A7,4),3))+0))

** array formulas need to be entered using the key
combination of CTRL,SHIFT,ENTER (not just ENTER).
Hold down both the CTRL key and the SHIFT key
then hit ENTER.