Last Minimum Value

[rasosa]

I have an example of a list of items that i have and next to it a quantity.

How can i bring the name of the last minimum value found?
I cannot rearange my information... Attached is I file with a very simple example...
Thank you!!

[Jonmo1]

Try

=LOOKUP(2,1/(D2:D8=MIN(D2:D8)),C2:C8)

[rasosa]

THank you!!!!
Could you explain to me why it is (2,/()
I don't understand the division

[Jonmo1]

Glad to help, thanks for feedback..

This part
1/(D2:D8=MIN(D2:D8))
Creates an array of the results of the devision
1/D2=MIN; 1/D3=MIN; 1/D4=MIN; etc
D2=MIN is just a true or false statement.
so you get results like
1/True; 1/False; 1/True

True=1, False=0, so it becomes
1/1; 1/0; 1/1

1/0 = error, 1/1 = 1 so it becomes
1; error; 1

Lookup then looks for a 2 in that array.
Lookup ignores errors, so it only sees the ones.
Since there are no numbers larger than 2 in the array, it finds the last number.
then it returns the corresponding value from C2:C8

Hope that helps.

[rasosa]

Thank you for the help and explanation!!!
of course it is a great help!!

[rasosa]

The previous formula worked perfect, but now i have some empty spaces... i have to select the exact range to cover only data.. how can i avoid this...

My problem is on the document

[Jonmo1]

In A36
=SMALL(A1:A34,1+COUNTIF(A1:A34,0))

In B36 and filled right to C36
=LOOKUP(2,1/($A4:$A34=$A36),B4:B34)

[rasosa]

The problem with that one is when i have several 0.00 or repeated values.... and i need the last minimum one

[Jonmo1]

So 0's in column A should count, but not Blanks ?

Insert a name
Formulas - Define New Name
name it VelMin (or whatever)
Refers to: =OFFSET(Sheet3!$A$4,0,0,COUNT(Sheet3!$A$4:$A$34),1)

Then in A36
=MIN(VelMin)
In B36 filled to C36
=LOOKUP(2,1/(VelMin=A36),B4:B34)

[Teethless mama]

Try this:

=LOOKUP(2,1/(A4:A34=MIN(A4:A34))/(A4:A34<>""),C4:C34)