multiple conditions with Function Sumif

Look to use the Sumifs function
http://www.techrepublic.com/blog/mso...-in-excel/6538

Try

=SUMIF($A$2:$A$8,"Activity 2", INDEX($B$2:$F$8,,MATCH(DATEVALUE("1/4/2013"),$B$1:$F$1,0)))

hi Punter, welcome to the forum. you dont need SUMIF if all you need is a single value. try:
=INDEX($B$2:$F$8,MATCH("Activity 2",$A$2:$A$8,0),MATCH(--("4jan13"),$B$1:$F$1,0))

or if there is a chance "Activity 2" appears more than once, then:
=SUMIF(A2:A8,"Activity 2",INDEX(B2:F8,,MATCH(--("4jan13"),B1:F1,0)))

"Activity 2" & --("4jan13") can be referred to a cell reference where such values exist

You're welcome…glad it worked out for you and thanks for the feedback...

ahhh luckily for Jeff's reply. i almost forgot to respond

there are 4 arguments available for use in INDEX, but i'm just using 3 parts of it; array, row_num, column_num.
array
$B$2:$F$8
this is the range where my desired results are

row_num
MATCH("Activity 2",$A$2:$A$8,0)
this is the row number my result is in, using the array range. if you manually count, "Activity 2" is the 2nd row of B2:F8. but using MATCH will help you not use manual calculation.

column_num
MATCH(--("4jan13"),$B$1:$F$1,0)
this is the column number my result is in, using the array range. if you manually count, "4-Jan-13" is the 4th column of B2:F8. but again, using MATCH will help you not use manual calculation.

so by manually keying in the row & column number, the INDEX should look like this:
=INDEX($B$2:$F$8,2,4)
meaning in B2:F8, i want the 2nd row & 4th column.

the MATCH formula has up to 3 arguments; lookup_value, lookup_array, match_type
lookup_value
the value we want to search for. for INDEX's row_num, we want to look for "Activity 2". and for INDEX's Column_num, we want to look for "4Jan13"

lookup_array
the range where we want to search in, using the lookup_value.

match_type
0 is for exact match. and that's what we want. only when the values are exactly the same, return the row or column number.

--("4jan13") by the way, is to convert the text of 4jan13 to a date Excel recognises. Excel recognises dates as numbers. change the format of B1:F1 as General & you'll see what i mean. hope that helps. if you're satisfied with the answer, please mark it as "Solved". my signature in the thread will guide you how to do that. thanks

@benishiryo,

I am very grateful to you. Thanks once gain for spending your precious time on helping me understand the Logic....You're a Champ

Moderators Note:

• As per Forum Rule #12, please don't quote whole posts unless necessary-- it's just clutter...Thanks.