Loop Search Text and cut/paste

This works but I don't know how to stop the loop (quit when it can't find "AR:") Thank you for any assistance

    Dim intRowCount As Integer
    intRowCount = Range("A1").CurrentRegion.Rows.Count - 1
  
 Do
     Cells.Find(What:="AR:", After:=ActiveCell, LookIn:=xlFormulas, LookAt:= _
        xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False _
        , SearchFormat:=False).Activate
    ActiveCell.Offset(0, 1).Range("A1:H1").Select
    Selection.Cut
    ActiveCell.Offset(-1, 1).Range("A1").Select
    ActiveSheet.Paste
    ActiveCell.Offset(0, -2).Range("A1").Select
    Cells.Find(What:="AR:", After:=ActiveCell, LookIn:=xlFormulas, LookAt:= _
        xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False _
        , SearchFormat:=False).Activate
    Selection.EntireRow.Delete
End

End Sub

Hi ker9... Welcome to the forum.

Be sure to read through the Forum Rules so you can use and follow them effectively. For instance, you'll need to EDIT that post above and put code tags around that code you used. (Like shown here...)

Option Explicit

Sub FindAndDelete()
Dim cFind   As Range

On Error Resume Next

    Do
        Set cFind = Cells.Find(What:="AR:", After:=[A1], _
            LookIn:=xlFormulas, LookAt:=xlPart, _
            SearchOrder:=xlByRows, SearchDirection:=xlNext, _
            MatchCase:=False, SearchFormat:=False)
        If Not cFind Is Nothing Then
            cFind.EntireRow.Delete
            Set cFind = Nothing
        Else
            Exit Sub
        End If
    Loop

End Sub

Thank you - sorry about that. I believe I fixed the original message.
Your response is not quite what I'm after but I appreciate the help very much.

(FYI: "AR:" is only in column A)
After I find "AR:", I need to go over 1 column and copy cells from 8 columns (B:I)
Then go up one row and paste starting in column C (C:J)
Then I can delete the row that contains AR

If I find AR and I am in the AR cell, this takes care of the copy/paste/delete. But with your code I don't seem to be in the AR cell that was found. I hope this makes sense.

ActiveCell.Offset(0, 1).Range("A1:H1").Select
Selection.Cut
ActiveCell.Offset(-1, 1).Range("A1").Select
ActiveSheet.Paste
ActiveCell.Offset(0, -2).Range("A1").Select
Cells.Find(What:="AR:", After:=ActiveCell, LookIn:=xlFormulas, LookAt:= _
xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False _
, SearchFormat:=False).Activate
Selection.EntireRow.Delete

Thank you - sorry about that. I believe I fixed the original message.
Your response is not quite what I'm after but I appreciate the help very much.

(FYI: "AR:" is only in column A)
After I find "AR:", I need to go over 1 column and cut cells from 8 columns (B:I)
Then go up one row and paste starting in column C (C:J)
Then I can delete the row that contains AR - or I supposed I could delete this after I do all the cutting and pasting

If I find AR and I am in the AR cell, this takes care of the copy/paste. But with your code I don't seem to be in the AR cell that was found. I hope this makes sense.

ActiveCell.Offset(0, 1).Range("A1:H1").Select
Selection.Cut
ActiveCell.Offset(-1, 1).Range("A1").Select
ActiveSheet.Paste
ActiveCell.Offset(0, -2).Range("A1").Select

1) Please edit your prior posts and use CODE tags, not quote tags. Just edit them and change the word QUOTE to CODE in the tags. Thanks.

2) I was really just trying to answer your specific question "how to loop for AR and stop when it's not found anymore". I assumed you would edit the code for the activities since I didn't exactly understand that part in your code.

Now that you've explained it this one line of added code will do the copy/paste:

        If Not cFind Is Nothing Then
            cFind.Offset(, 1).Resize(1, 8).Copy cFind.Offset(-1, 1)
            cFind.EntireRow.Delete
            Set cFind = Nothing
        Else

3) You'll note the absence of selecting and activecell and such. Only humans need to select a cell before acting on it. In VBA, you can refer to cells and ranges directly and act on them directly without selecting at all.

I'm using a range variable to spot the "AR:" cells, so when it's found the address of the cell is stored in that variable and we can offset from there without selecting.

In general, you want to remove as many physical references as you can.

My pleasure, glad to help. The 3 hours is well spent if you end up with:

1) The correct solution to the problem at hand
2) A new resource for getting more correct solutions in the future


===========

If that takes care of your need, please click EDIT in your original post, click GO ADVANCED and set the PREFIX box to SOLVED.

You can control what gets searched in the RANGE reference underlined here:

Option Explicit

Sub FindAndDelete()
Dim cFind   As Range

On Error Resume Next

    Do
        Set cFind = Range("B:B").Find(What:="AR:", After:=[A1], _
            LookIn:=xlFormulas, LookAt:=xlPart, _
            SearchOrder:=xlByRows, SearchDirection:=xlNext, _
            MatchCase:=False, SearchFormat:=False)
        If Not cFind Is Nothing Then
            cFind.Offset(, 1).Resize(1, 8).Copy cFind.Offset(-1, 1)
            cFind.EntireRow.Delete
            Set cFind = Nothing
        Else
            Exit Sub
        End If
    Loop

End Sub

It doesn't work when I do that (and yes I made sure I had the correct column to find it) It only works when it starts with "cells" as in the original.
EXCEPT - if I change: After:=[A1] to After:=[B1]
Then it works

Thank you again - You're wonderful!!!