setting up formula to drag

I need some help manipulating data into a usable format with some additional calculations. Here is a sample of what it looks like in Excel (Letters at top and Numbers on left are excel spreadsheet inputs; all others are part of the data file):

A B C D E F G H I J K L M
1 1 2 3 4 5 6 7 8 9 10 11 12
2 A 25 27 49 13 15 21 24 21 17 305 327 343
3 B
4 C
5 D
6 E
7 F
8 G
9 H
10
11 Read 2:EM Spectrum
12 Wavelength 5 (579 nm)
13 1 2 3 4 5 6 7 8 9 10 11 12
14 A 21 17 38 17 22 22 27 21 23 338 349 354
15 B
16 C
17 D
18 E
19 F
20 G
21 H

Every 3 data points I need to take the average. I set up another sheet to condense the data and get rid of the extra lines (ie B-H) like this:

*Column A on separate spreadsheet*
AVERAGE(B2:D2)
AVERAGE(E2:G2)
AVERAGE(H2:J2)
AVERAGE(K2:M2)

*Column B on separate spreadsheet*
AVERAGE(B14:D14)
AVERAGE(E14:G14)
AVERAGE(H14:J14)
AVERAGE(K14:M14)

Now I have over 140 series like this and want to drag and drop the formula to take the AVERAGE and eventually STDEV of all of them. The problem is each time I drag to fill the formula into the next column (C to infinity) it just shifts the data series to the left so now it is:

*Column C on separate spreadsheet*
AVERAGE(E2:G2)
AVERAGE(H2:J2)
AVERAGE(K2:M2)
AVERAGE(N2:P2)

*Column D on separate spreadsheet*
AVERAGE(E14:G14)
AVERAGE(H14:J14)
AVERAGE(K14:M14)
AVERAGE(N14:P14)

When I really want it to have Column C look like this:
AVERAGE(B26:D26)
AVERAGE(E26:G26)
AVERAGE(H26:J26)
AVERAGE(K26:M26)

I'm not sure what I'm missing. I've tried setting up 4-5 columns with the *correct* formula, highlighted all 4-5 columns with said formulas, and dragged the formula with the same result of the shift to the left happening. Any ideas on how to make this work that don't involve me typing in each formula for all 140 points?

Well i wouldn't recommend it buy in col A
=AVERAGE(INDIRECT("B"&COLUMN()*12-10&":D"&COLUMN()*12-10))
will increment
2,14,26........

If I have understood you correctly I think you want the following

Averages Sheet ! A1
=AVERAGE(INDEX(Sheet1!$B$1:$IV$2000,2+(12*(COLUMNS($A1:A1)-1)),1+(3*(ROWS(A$1:A1)-1))):INDEX(Sheet1!$B$1:$IV$2000,2+(12*(COLUMNS($A1:A1)-1)),3+(3*(ROWS(A$1:A1)-1))))

The above can be copied down and across as required ...

An alternative using OFFSET which though easier to follow is Volatile (bad) would be:

Averages Sheet ! A1
=AVERAGE(OFFSET(Sheet1!$B$2,12*(COLUMNS($A1:A1)-1),3*(ROWS(A$1:A1)-1),1,3))

Again like the above this could be copied down and across as required.

If it's possible you may have #DIV/0! errors arising from your formulae (ie empty data sets being averaged) you could encase either of the above within something along the lines of:

=LOOKUP(9.99999999999999E+307,CHOOSE({1,2},0, one of above formulae))

This would return 0 instead of #DIV/0!

I hope that helps.