Calculate series of numbers with different values

Hello,
I would thank you if you could help me. I have the next problem:

A list of numbers from 1 (column A), with values ( column B) that indicates the number of times that repeats the number of column A:
1 2(times)
2 0
3 1
4 0
5 3
6 2
7 0
8 0
9 2
10 1
11 0
12 2
13 1
14 5
15 0
16 1
17 2
...

What I want is, in the next column (C), find the result of this operation:
I take 12 numbers in order: from 1 to 12, from 2 to 13, from 3 to 14, etc.
With every 12 numbers I make the next:
The first number sum 11, the second 10, the third 9, the forth 8, the fifth 7, the sixth 6, the seventh 5, the eighth 4, the ninth 3, the tenth 2, the eleventh 1, and the twelfth 0. But the numbers that cames after subtract 12, and those that cames behind values 0.

Then I want to calculate the result of the value of the number of Column A multiply for the number in the column B

The values will be like this, if we start from 1 (This is not the result I'm searching, but just for explain the values of every row):

1 2 +11*2 = +22
2 0 +10*0 = 0
3 1 +9*1 = +9
4 0 +8*0 =0
5 3 +7*3=+21
6 2 +6*2=+12
7 0 +5*0=0
8 0 +4*0=0
9 2 +3*2=+6
10 1 +2*1=2
11 0 +1*0=0
12 2 +0*2=0
13 1 -12
14 5 -12
15 0 -12
16 1 -12
17 2 -12

What I'm looking is the result of this values:
+22+9+21+12+6+2-12-12-12-12-12= +12
This is the result of the first row.

The second Row will be like this:
Values:
1 2 0
2 0 +11*0
3 1 +10*1
4 0 9*0
5 3 8*3
6 2 7*2
7 0 6*0
8 0 5*0
9 2 4*2
10 1 3*1
11 0 2*0
12 2 1*2
13 1 0*1
14 5 -12
15 0 -12
16 1 -12
17 2 -12

We can see here that row 1 have now a value of 0, because we left behind. The result will be:
+10+24+14+8+3+2-12-12-12-12=+13

Then the result of the second row (the result of start to calculate from this second row) is 13

Then the results will be like this:
1 2 +12
2 0 +13
3 1 ...
4 0
5 3
6 2
7 0
8 0
9 2
10 1
11 0
12 2
13 1
14 5
15 0
16 1
17 2 +22

And with the formula we could find the rest of results.
When we arrive to the last row, in this case 17, the calculation will be the next:
All the values behind will be 0, and 17 values 11*2=22

Thank you very much for your help,
Regards,
Caldera

Assuming that A2:B18 contains the data, try...

C2, confirmed with CONTROL+SHIFT+ENTER, and copied down:

=INDEX(MMULT(TRANSPOSE(ROW($B$2:$B$18)^0),IF((ROW($A$2:$A$18)-ROW($A$2)+1>=1+TRANSPOSE(ROW($A$2:$A$18)-ROW($A$2)))*(ROW($A$2:$A$18)-ROW($A$2)+1<=12+TRANSPOSE(ROW($A$2:$A$18)-ROW($A$2))),($B$2:$B$18)*(12-(ROW($A$2:$A$18)-ROW($A$2)+1)+TRANSPOSE(ROW($A$2:$A$18)-ROW($A$2))),IF(ROW($A$2:$A$18)-ROW($A$2)+1<TRANSPOSE(ROW($A$2:$A$18)-ROW($A$2)+1),0,-12))),ROWS(C$2:C2))

Hope this helps!

Try...

C2, confirmed with CONTROL+SHIFT+ENTER, and copied down:

=SUM(IF(ROW($B2:$B$62)-ROW($B2)+1<=12,($B2:$B$62)*(12-(ROW($B2:$B$62)-ROW($B2)+1)),IF($B2:$B$62>0,-12)))

Hope this helps!

Thank you very much, Domenic.

It's great.
I don't know how I could to give you thanks.
I made another mistake in my explanation, but I did found how to solve the problem:
it was that in the -12 rows there is more value than one, it has to multiply for that number. I analyze the formula, and then I add this:

=SUM(IF(ROW($B2:$B$62)-ROW($B2)+1<=12,($B2:$B$62)*
(12-(ROW($B2:$B$62)-ROW($B2)+1)),IF($B2:$B$62>0,-12*$B2:$B$62)))

In spanish:
=SUMA(SI(FILA($B2:$B$62)-FILA($B2)+1<=12;($B2:$B$62)*
(12-(FILA($B2:$B$62)-FILA($B2)+1));SI($B2:$B$62>0;-12*$B2:$B$62)))

It's just a detail, but it makes me very happy, that works so fine.

I give you a present, that is too a present for everybody that had help me. It's a photograph I made, that I like so much, and give me good feeling, and calmness.

You're very welcome! And thanks for the feedback! By the way, nice photograph!