Page name from cell or vice versa

Hey guys,
I am trying to create a production report that has a cover, and then many pages that the cover references. I want to be able to either fill in the corrisponding cell on the cover and the correct page gets named. Then I want a cell in the page to name itself after the Page. For example the cover would get typed to look like..

Job 1
Job 2
Job 3

Then the tabs would automatically get named Job 1 Job 2 Job 3

I'm not sure if its possible, but any help is appreciated.

p.s. Naming tabs and the cell fills in correctly works also, either way

Audi,
With a blank workbook open type your desire sheet names in cell A1, A2,... and so on

1. Then Press Alt+F11 on your keyboard. You will open the Visual Basic Editor.
2. Double click Sheet on on the Project properties (top right corner)
3. On the Right side (the white space) paste the following VBA code

Sub CreateSheetsFromList()
    Dim R As Range
    For Each R In Selection.Cells
        If R.Text <> vbNullString Then
            If SheetExists(R.Text, ThisWorkbook) = False Then
                With ThisWorkbook.Worksheets
                    .Add(after:=.Item(.Count)).Name = R.Text
                End With
            End If
        End If
    Next R
End Sub


Private Function SheetExists(SHName As String, WB As Workbook) As Boolean
    On Error Resume Next
    SheetExists = CBool(Len(WB.Worksheets(SHName).Name))
End Function

Courtesy of CPearson

4. Close the VB Editor and Select your list
5. Open the Visual Basic toolbar (View >Toolbars>Visual Basic)
6. Run the Sub CreateSheetsFromList macro

Note: The code tests whether a sheet already exists with the particular name, and won't create a new sheet if that name is already in use, but it doesn't test whether the name is valid for a new worksheet (i.e. funny characters "&","/", et al).

Regards,
nrage21