reshuffling over blank cell in a row

[UZR1]

I wish to move cell data from row, over blank cells and fill the gap to keep them to extreme left

Refer to aatchament.

Please help

[windknife]

Try this,

=LET(
   a,TRIMRANGE(A1:E100),
   DROP(REDUCE("",SEQUENCE(ROWS(a)),LAMBDA(x,y,VSTACK(x,TOROW(INDEX(a,y,),1)))),1)
)

[TMS]

Please review your previous thread: https://www.excelforum.com/excel-for...ml#post6019255

[TMS]

If there are only two entries on a row, this would work:

=WRAPROWS(TOROW(A1:E4,1),2)

If there are, potentially, any number of entries on a row, windknife's solution would need tweaking.

=LET(
   a,TRIMRANGE(A1:E100),
   IFERROR(DROP(REDUCE("",SEQUENCE(ROWS(a)),LAMBDA(x,y,VSTACK(x,TOROW(INDEX(a,y,),1)))),1),"")
) 

[TMS]

If that takes care of your original question, please select Thread Tools from the menu link above and mark this thread as SOLVED.

Also, you may not be aware that you can thank those who have helped you by clicking the small star icon (Next to Add Reputation) located in the lower left corner of the post in which the help was given. By doing so you can add to the reputation(s) of those who helped.

[djclements]

A couple of alternative approaches include:

=LET(
   a, A1:E4,
   b, ISBLANK(a),
   n, COLUMNS(a),
   i, SEQUENCE(ROWS(a)),
   j, SEQUENCE(, n),
   WRAPROWS(SORTBY(TOCOL(IF(b, "", a)), TOCOL(IF(j, i)), 1, TOCOL(IF(b, n + 1, j)), 1), n)
)

And:

=LET(
   a, BYROW(A1:E4, LAMBDA(r, TEXTJOIN("|",, COUNTA(r), r))),
   n, --TEXTBEFORE(a, "|"),
   m, MAX(n),
   TEXTSPLIT(TEXTAFTER(a & REPT("|", 1 + m - n), "|", SEQUENCE(, m)), "|")
)

Adjust the range reference as needed.