Index a result which is the value above a threshold in a time range on a date

[Rossyb76]

Hi,

Seeing if anyone can help me here as my Excel skills are average at best!

I am looking for a formula to do the following:

Display the specific time when a value crosses a set threshold for the first time within a specific timerange on a specific date.

My research had prodouced the formula below so far:

=IFERROR(INDEX($B$2:$B$28,MATCH(TRUE,($A$2:$A$28>G2)*($B$2:$B$28>=D2)*($B$2:$B$28<=E2)*($C$2:$C$28=F2),0)),"No match")

The columns on my sheet are A is list of values, B List of times, C List of dates, D Start time, E End Time, F Specific date, G is Threshold value.

This may be totally wrong im not sure. All I know is it doesnt work.

I have attached the sheet with all this in.

Any help appreciated

Many Thanks Ross

[TMS]

This would do it:

=TAKE(FILTER(B2:B28,(C2:C28=F2)*(B2:B28>=D2)*(B2:B28<=E2)*(A2:A28>=G2)),1)

That said, none of the times are true numeric time values, and none of the dates are true numeric date values. They are all text values that look a bit like dates and times. You can check by changing the format to General. If they change to numbers, they are true dates/times. If they don't, they're not.

Edit:

=TAKE(FILTER(B2:B28,(C2:C28=F2)*(B2:B28>=D2)*(B2:B28<=E2)*(A2:A28>=G2),"no match"),1)

copes with the target value not being found.

[TMS]

Incidentally, this also works for non 365:

=IFERROR(INDEX($B$2:$B$28,MATCH(1,($A$2:$A$28>G2)*($B$2:$B$28>=D2)*($B$2:$B$28<=E2)*($C$2:$C$28=F2),0)),"No match")

[Rossyb76]

Thanks for the response that works great

Much appreciated

Ross

[TMS]

You're welcome.



If that takes care of your original question, please select Thread Tools from the menu link above and mark this thread as SOLVED.

Also, you may not be aware that you can thank those who have helped you by clicking the small star icon located in the lower left corner of the post in which the help was given. By doing so you can add to the reputation(s) of those who helped.