Formulas do not travel between workbooks - they keep pointing to the original source

You can use the link tool (under the data tab) to change the source from workbook 1 to workbook 2.

If your 'tools' include macros, then you may have a different problem.

What I sometimes to is select the entire sheet, run the first macro, copy it into the second book, and then run the second macro.

Sub FormulaToText()
    Dim myCell As Range
    Dim myCalc As Variant
    
    With Application
        .ScreenUpdating = False
        myCalc = .Calculation
        .Calculation = xlCalculationManual
        .EnableEvents = False
    End With
    
    On Error Resume Next
    
    For Each myCell In Selection.SpecialCells(xlCellTypeFormulas)
        If myCell.HasArray Then
            myCell.Formula = "'AF" & myCell.Formula
        Else
            myCell.Formula = "'" & myCell.Formula
        End If
    Next myCell
    
    With Application
        .ScreenUpdating = True
        .Calculation = myCalc
        .EnableEvents = True
    End With
End Sub

Sub TextToFormula()
    Dim myCell As Range
    Dim myCalc As Variant
    
    With Application
        .ScreenUpdating = False
        myCalc = .Calculation
        .Calculation = xlCalculationManual
        .EnableEvents = False
    End With
    
    On Error Resume Next
    
    For Each myCell In Selection.SpecialCells(xlCellTypeConstants, xlTextValues)
        If Left(myCell.Formula, 1) = "=" Then myCell.Formula = myCell.Text
        If Left(myCell.Formula, 3) = "AF=" Then myCell.FormulaArray = Mid(myCell.Text, 3, Len(myCell.Text))
    Next myCell
    
    With Application
        .ScreenUpdating = True
        .Calculation = myCalc
        .EnableEvents = True
    End With
End Sub