transpose X matching headers X duplicate tables (multiple problems)

Solution!A1:

Formula:

='Original Data'!A1

Fill right into B1:J1. Select A1:H1 and fill down into A2:H7.

Solution!A8:

Formula:

=A2

Fill right into B8:H8.

Solution!I2:

Formula:

=INDEX('Original Data'!$K$1:$R$1,ROUNDUP(ROWS(I$2:I2)/6,0))

Solution!J2:

Formula:

=HLOOKUP(I2,'Original Data'!$K$1:$R$7,2+MOD(ROWS(J$2:J2)-1,6),0)

Select I2:J2 and fill down into I3:J8.

Select A8:J8, and fill down until formulas in column J produce errors.

This is specific to 8 columns of attributes and 6 rows of values. For varying number of attribute columns and value rows, BUT plain data still in 'Original Data'!A:H, better to use 1 additional cell.

Solution!AAB1:

Formula:

=MATCH(1,0/NOT(ISBLANK('Original Data'!A:A)))-1

Solution!A1:

Formula:

=IF(ROWS(A$1:A1)-1<=$AAB$1,'Original Data'!A1,INDEX(A$1:A1,2+MOD(ROWS(A$1:A1)-2,$AAB$1)))

Fill A1 right into B1:J1. Select A1:H1 and fill down into A2:H2.

Solution!I2:

Formula:

=INDEX('Original Data'!$K$1:$ZZ$1,ROUNDUP(ROWS(I$2:I2)/$AAB$1,0))

Solution!J2:

Formula:

=HLOOKUP(I2,'Original Data'!$K$1:$ZZ$7,2+MOD(ROWS(J$2:J2)-1,$AAB$1),0)

Select A2:J2 and fill down until formulas in column J produce errors.