Complex Usage of Concatenate Formula

If you really mean you're using Excel 2019, then your 2nd sample data would be easier to use. If it were in the same workbook as your results in a worksheet named Sample2, then with results beginning in another workbook in cell A21,

A21: =Sample2!A2
B21: =Sample2!B2
C21: =TEXTJOIN(",",1,INDEX(Sample2!C$2:C$1000,D21):INDEX(Sample2!C$2:C$1000,D21+E21-1))
D21: 1
E21: =COUNTIF(Sample2!A$2:A$1000,A21)

A22: =INDEX(Sample2!A$2:A$1000,$D22)
B22: =INDEX(Sample2!B$2:B$1000,$D22)
C22: =TEXTJOIN(",",1,INDEX(Sample2!C$2:C$1000,D22):INDEX(Sample2!C$2:C$1000,D22+E22-1))
D22: =D21+E21
E22: =COUNTIF(Sample2!A$2:A$1000,A22)

A similar approach could be used with the first sample, but the formulas are more complicated/longer. Col A would show e-mail address, col B property name, col C comma-separated list of services, col D top row number in sample data (assumed beginning in row 2) for e-mail address in col A, and col E is the number of rows in sample data which the e-mail in col A appears. The key to the col C formulas is the TEXTJOIN function, which isn't available in Excel prior to Excel 2019.

If you don't actually have Excel 2019, Excel Online provides TEXTJOIN and so does Google Sheets. So if you actually have an older version of Excel, you may need to use an online spreadsheet to do this.

ADDED: If you don't have Excel 2019, you could use older versions, but different formulas. If sample 2 were in a worksheet named Sample2, add a column of formulas to it.

D2: =IF(A2<>A1,C2,D1&","&C2)

Fill D2 down as far as there's data in cols A to C.

In the results worksheet, change the col C formulas to

C21: =INDEX(Sample2!D$2:D$1000,D21+E21-1)

Fill C21 down as far as needed.