display all row containing string from Both Dropdown list

i have attached my sample file

Attach a sample workbook (not image).

OP has done so.

in H14

=IFERROR(INDEX($C$2:$C$19,SMALL(IF(($F$8=$A$2:$A$19)*($G$8=$B$2:$B$19),ROW($A$2:$A$19)-ROW($A$2)+1,""),ROWS($A$2:A2))),"")

...confirmed by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. You will know the array is active when you see curly braces { } appear around your formula. If you do not CTRL+SHIFT+ENTER you will get an error or a clearly incorrect answer.

Copy down

Put this in F14

=IFERROR(INDEX(A$2:A$19,SMALL(IF(($F$8=$A$2:$A$19)*($G$8=$B$2:$B$19),ROW($A$2:$A$19)-ROW($A$2)+1,""),ROWS($A$2:A2))),"")

...confirmed by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. You will know the array is active when you see curly braces { } appear around your formula. If you do not CTRL+SHIFT+ENTER you will get an error or a clearly incorrect answer.

Copy across and down

Thanks John, i had figured it out, it was my silly typing mistake. thanks you so much for the Formula

i need little more help
i need to display all data related to first drop down selected.

i have attached my sample file. pl Help
for e.g.

Dropdown1: West and DropDown2: "All" (or a Blank is displayed)

Region | Circle          |  Fruits
-----------------------------------
West	  | Mumbai       | Mango
West	  | Mumbai       |  Apple
West	  | Mumbai       | Grapes
West	  | Mumbai       | Strawberry
West	  | Mumbai       | Kiwi
West	  | Mumbai       | Mango
West	  | Maharashtra | Apple
West	  | Maharashtra | Grapes
West	  | Maharashtra | Strawberry
West	  | Maharashtra | Kiw

i
and

Dropdown1: West and DropDown2: Mumbai

Region | Circle    |  Fruits
----------------------------
West	  | Mumbai | Mango
West	  | Mumbai | Apple
West	  | Mumbai | Grapes
West	  | Mumbai | Strawberry
West	  | Mumbai | Kiwi
West	  | Mumbai | Mango

In F14

=IFERROR(INDEX(A$2:A$19,SMALL(IF(($F$8=$A$2:$A$19)*IF($G$8="ALL",1,($G$8=$B$2:$B$19)),ROW($A$2:$A$19)-ROW($A$2)+1,""),ROWS($A$2:A2))),"")

...confirmed by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. You will know the array is active when you see curly braces { } appear around your formula. If you do not CTRL+SHIFT+ENTER you will get an error or a clearly incorrect answer.

Copy across and down

Thanks once again for saving my lots of work, with you help and support

You are very welcome.