Need formulas to find and copy maching cells

[EdvinasS]

Hello,

I need a big help. I have excel file with two sheets in it ( Sheet1 and Sheet2 )
I need to compare Sheet1 A1 with Sheet2 C10:100 and if there are any duplicates than copy all row (with duplicate cell) from Sheet 1 and Sheet 2 to New Sheet 3, and same is with Sheet 1 A2, A3 till A500

In simple if Sheet 1 column A1 is same as Sheet 2 column C50 then copy all row with column A1 ( Sheet 1 ) and all row with column C50 ( Sheet 2 ) to Sheet 3 A1 and A2 rows

Thank you very much.

[Glenn Kennedy]

Will you please attach a SMALL sample Excel workbook (10-20 rows of data is usually enough)? Please don't attach a picture of one (no-one will want to re-type all your stuff before starting).

1. Make sure that your sample data are truly REPRESENTATIVE of your real data. The use of unrepresentative data is very frustrating and can lead to long delays in reaching a solution.

2. Make sure that your desired solution is also shown (mock up the results manually).

3. Make sure that all confidential information is removed first!!

4. Try to avoid using merged cells. They cause lots of problems!

Unfortunately the attachment icon doesn't work at the moment. So, to attach an Excel file you have to do the following: Just before posting, scroll down to Go Advanced and then scroll down to Manage Attachments. Now follow the instructions at the top of that screen.

[EdvinasS]

Attached.

Thanks.

[Glenn Kennedy]

I think I understand what ypu want.. but rather than leave me guessing, please amend your sheet to show what your anticipated results are. I don't fully understand your written description.

[EdvinasS]

I'll showed that i found one and another one duplicates in sheet 1 and 2 and copied these two lines to sheet 3, i done it by hand, but i need formula. I was tryink vlookup match counfit but i really miss info in my head by using larger formulas in excel than sum or count

Thanks a lot

[EdvinasS]

Hello, so could any help with this question?

Thank you

[Glenn Kennedy]

Apols. I've been away. These are all array formulae:

To return the duplicate data from sheet 1, copied across and down:
=IFERROR(INDEX(Sheet1!A:A,SMALL(IF(ISNUMBER(MATCH(Sheet1!$A$1:$A$12,Sheet2!$C$10:$C$21,0)),ROW(Sheet1!$A$1:$A$12)),ROWS(A$7:A7))),"")

To return the duplicate data from sheet 2, copied across and down:
=IFERROR(INDEX(Sheet2!A:A,SMALL(IF(ISNUMBER(MATCH(Sheet2!$C$10:$C$21,Sheet1!$A$1:$A$12,0)),ROW(Sheet2!$C$10:$C$21)),ROWS(A$14:A14))),"")

They can be combined to return the data on alternate rows, but it is more complicated again!! Use this, copied across and down.

=IFERROR(IF(ISODD(ROWS(H$7:H7)),INDEX(Sheet1!A:A,SMALL(IF(ISNUMBER(MATCH(Sheet1!$A$1:$A$12,Sheet2!$C$10:$C$21,0)),ROW(Sheet1!$A$1:$A$12)),1+INT((ROWS(H$7:H7)-1)/2))),INDEX(Sheet2!A:A,SMALL(IF(ISNUMBER(MATCH(Sheet2!$C$10:$C$21,Sheet1!$A$1:$A$12,0)),ROW(Sheet2!$C$10:$C$21)),1+INT((ROWS(H$7:H7)-1)/2)))),"")

Array Formulae are a little different from ordinary formulae in that they MUST be confirmed in the FIRST CELL ONLY by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. After that, the array can be dragged down as normal, to cover the desired range.

You will know the array is active when you see curly brackets { } - or "curly braces" for those of you in the USA, or "flower brackets" for those of you in India - appear around the outside of your formula. If you do not use CTRL+SHIFT+ENTER you will (almost always) get an error message or an incorrect answer. Press F2 on that cell and try again.

Don't type the curly brackets yourself - it won't work...

Take the formulae from the sheet, as they'll have the , and ; correct for your country.