Matching a Cell with multiple entries

[hemants]

Hi,

I have this formula:
=INDEX($A$6:$A$19,MATCH($B$22,H6:H19,0))

And it finds a Value (ex: G2) in the range H6:H19

What if the cell has more than 1 value, example cell H8 has the value "G2, G3".

How can I modify the formula above to find both of them when I alternate the value of B22.

B22 has a pull-down list: G1, G2, G3, G4

[Glenn Kennedy]

Assuming you wan the answer in C22, and down from there:

=IFERROR(INDEX($A:$A,SMALL(IF(ISNUMBER(SEARCH($B$22,$H$6:$H$19)),ROW($H$6:$H$19)),ROWS(C$22:C22))),"")

enter as an array formula. Array Formulae are a little different from ordinary formulae in that they MUST be confirmed in the FIRST CELL ONLY by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. After that, the array can be dragged down as normal, to cover the desired range.

You will know the array is active when you see curly brackets { } - or "curly braces" for those of you in the USA, or "flower brackets" for those of you in India - appear around the outside of your formula. If you do not use CTRL+SHIFT+ENTER you will (almost always) get an error message or an incorrect answer. Press F2 on that cell and try again.

Don't type the curly brackets yourself - it won't work...

[FlameRetired]

Another version. Array entered also.

=INDEX($A$6:$A$19,SMALL(IF($B$22=$H$6:$H$19,ROW($A$6:$A$19)-MIN(ROW($A$6:$A$19))+1),ROWS($6:6)))

[hemants]

Here is the file, I highlighted the cells I am talking about.

[FlameRetired]

Try entering this in B24 and fill down.

=INDEX($A$6:$A$19,MATCH(1,MMULT(ISNUMBER(FIND($B$22,$B$6:$K$19))*($A24=$B$5:$K$5),{1;1;1;1;1;1;1;1;1;1}),0))

[hemants]

Try entering this in B24 and fill down.

=INDEX($A$6:$A$19,MATCH(1,MMULT(ISNUMBER(FIND($B$22,$B$6:$K$19))*($A24=$B$5:$K$5),{1;1;1;1;1;1;1;1;1;1}),0))

THIS WORKS PERFECTLY!!!!!!

just had to say it like that

[Glenn Kennedy]

Or indeed this (a bit slow tonight), in B24, copied down:

=INDEX(A:A,SUMPRODUCT((ISNUMBER(SEARCH($B$22,$B$6:$L$20))*($B$5:$L$5=A24)*ROW($B$6:$L$20))))

[FlameRetired]

Glad to hear it! Thanks for the feedback.