Handling Duplicate Entries with Index/Match/Large in Column Data

[TwiceBorn]

I have a worksheet for tallying attrition occurrences for various teams. Currently, I have two columns that are meant to calculate the largest and second largest occurrence and concatenate the reason with the % of the total attrition for the team. The first of the two columns does fine, but when the second column is faced with two reasons with the same number of occurrences, it will always return the same value as the first column.

I've seen a number of threads for dealing with this when the data is formatted in in rows, but mine has to be in columns like this. I've provided the dummy data of what it is currently doing, along with the second sheet that displays what I am trying to get it to do. Thanks in advance.

[JeteMc]

This solution employees a helper table,D11:J18 , which can be hidden for aesthetic purposes. The formula for the helper column cells is in the form:

=IFERROR(D2*(1-COLUMN()*0.001),"")

The formula for the second reason is then modified to read:

=IF(ISERROR(LARGE($D11:$J11,2)),"",CONCATENATE(INDEX($D$1:$J$1,MATCH(LARGE($D11:$J11,2),$D11:$J11,0))," ", TRUNC(LARGE($D2:$J2,2)/SUM($D2:$J2),2)*100,"%"))

Let me know if you have any questions.

[FlameRetired]

Another way.

Try array-entering this formula in B2 and fill down and across.

=IF(ISERROR(LARGE($D2:$J2,COLUMNS($B:B))),"",CONCATENATE(INDEX($D$1:$J$1,SMALL(IF(LARGE($D2:$J2,COLUMNS($B:B))=$D2:$J2,COLUMN($D:$J)-MIN(COLUMN($D:$J))+1),MIN(COLUMNS($B:B),IF($D2:$J2<>"",COUNTIF($D2:$J2,$D2:$J2)))))," ", TRUNC(LARGE($D2:$J2,COLUMNS($B:B))/SUM($D2:$J2),2)*100,"%"))

If you aren’t familiar with array-entered formulas array enter means the formula must be committed from edit mode by simultaneously pressing and holding down Ctrl and Shift while hitting Enter.

[soledad]

you can apply the following formula

C2=LOOKUP(1,1/(RANK(D2:J2,D2:J2,1)*COLUMN(J:J)-COLUMN(D:J)=LARGE(IF(D2:J2<>"",RANK(D2:J2,D2:J2,1)*COLUMN(J:J)-COLUMN(D:J)),2)),D$1:J$1&" "&TRUNC(D2:J2/SUM(D2:J2),2)*100&"%")

confirm with ctrl+shift+enter

[soledad]

you can apply the following formula

C2=LOOKUP(1,1/(RANK(D2:J2,D2:J2,1)*COLUMN(J:J)-COLUMN(D:J)=LARGE(IF(D2:J2<>"",RANK(D2:J2,D2:J2,1)*COLUMN(J:J)-COLUMN(D:J)),2)),D$1:J$1&" "&TRUNC(D2:J2/SUM(D2:J2),2)*100&"%")

confirm with ctrl+shift+enter

[JeteMc]

Yet one more array entered formula, for B2 across and down, that will not require the use of a 'helper':

=IF(ISERROR(LARGE($D2:$J2,COLUMN(A1))),"",CONCATENATE(INDEX($D$1:$J$1,MATCH(LARGE(IFERROR($D2:$J2-COLUMN(D2:J2)*0.001,FALSE),COLUMN(A1)),IFERROR($D2:$J2-COLUMN(D2:J2)*0.001,FALSE),0))," ", TRUNC(LARGE($D2:$J2,COLUMN(A1))/SUM($D2:$J2),2)*100,"%"))

Let me know if you have any questions.

[TwiceBorn]

Thanks everyone for the quick replies. I tried each of your solutions, and was able to make each work with my real data. I decided on FlameRetired's solution for now. We'll see how performance is in the bigger file down the road. You are all awesome!

[FlameRetired]

TwiceBorn,

You're welcome. Glad all solutions work. Thanks for the feedback and the rep.