Good day
I have this formula
=SUMIFS('GC-2016-06-17'!$J$2:$J$361,'GC-2016-06-17'!$G$2:$G$361,">="&'Money Tracker 2016-06-20'!Q$1,'GC-2016-06-17'!$G$2:$G$361,"<="&'Money Tracker 2016-06-20'!Q$2)
I would like to left drag paste it, and keep everything as it, except my Q1 & Q2 must NOT become P1 & P2, I want it to become R1 and R2.
Thus, drag paste in "reverse"? From Cell N8 to Cell M8, L8, K8, J8, I8, etc
Hope this is clear enough and that some very clever excel fundi can help me please?
Thx
So as your formula is copied left you want the references to advance to the right?
Dave
Hi Dave, yes sort of.
I want to keep my entire formula the same and just change Q1 to R1, S1 etc but by copying it to the left.
Hello cng,
Welcome to the forum
Try this formula then
Post it in Column Q, if you drag it left or right from Q, Q1 and Q2 will only go forward to the right to R1 R2, S1 S2, etc.
=SUMIFS('GC-2016-06-17'!$J$2:$J$361,'GC-2016-06-17'!$G$2:$G$361,">="&INDIRECT("'Money Tracker 2016-06-20'!"&ADDRESS(1,17+ABS(17-COLUMN()),4)),'GC-2016-06-17'!$G$2:$G$361,"<="&INDIRECT("'Money Tracker 2016-06-20'!"&ADDRESS(1,17+ABS(17-COLUMN()),4)))
All I did was replacing 'Money Tracker 2016-06-20'!Q$1 with INDIRECT("'Money Tracker 2016-06-20'!"&ADDRESS(1,17+ABS(17-COLUMN()),4)) (Similar for Q2)
(copy pasta from Ford)
1. Use code tags for VBA. [code] Your Code [/code] (or use the # button)
2. If your question is resolved, mark it SOLVED using the thread tools
Regards,
Lem
Thanx Lem, I tried this, but maybe I am just in over my head, it does not work...
I am not GREAT with excel... I just want it to count up when I left copy instead of down. I copied your INDIRECT("'Money Tracker 2016-06-20'!"&ADDRESS(1,17+ABS(17-COLUMN()),4)) (Similar for Q2) it still won't work.
Try to paste
="'Money Tracker 2016-06-20'!"&ADDRESS(1,17+ABS(17-COLUMN()),4)
In Q10 or something, and drag it left / right then, it should work (just to confirm that part)
Probably I messed it up for Q2, so use this formula instead
=SUMIFS('GC-2016-06-17'!$J$2:$J$361,'GC-2016-06-17'!$G$2:$G$361,">="&INDIRECT("'Money Tracker 2016-06-20'!"&ADDRESS(1,17+ABS(17-COLUMN()),4)),'GC-2016-06-17'!$G$2:$G$361,"<="&INDIRECT("'Money Tracker 2016-06-20'!"&ADDRESS(2,17+ABS(17-COLUMN()),4)))
Last edited by Lemice; 06-20-2016 at 04:45 AM.
If you starting in Column N try
in N8
=SUMIFS('GC-2016-06-17'!$J$2:$J$361,'GC-2016-06-17'!$G$2:$G$361,">="&INDIRECT("'Money Tracker 2016-06-20'!"&ADDRESS(1,16+ABS(15-COLUMNS($A:N)),4)),'GC-2016-06-17'!$G$2:$G$361,"<="&INDIRECT("'Money Tracker 2016-06-20'!"&ADDRESS(2,16+ABS(15-COLUMNS($A:N)),4)))
Thank you Dave, This worked perfectly! Fantastic!
There are currently 1 users browsing this thread. (0 members and 1 guests)
Posting Permissions
LinkBack URL
About LinkBacks
Register To Reply
Bookmarks