Extract values

[bjnockle]

Looking for formula to extract values into column A2:A20. Column K and L are the two columns where the data resides for the data pull. Sample file attached

Thanks

[FDibbins]

Try this, copied down...
=INDEX(L:L,MATCH(B2,K:K,0))

[bjnockle]

FDibbins: formula is not pulling the right values.

[FDibbins]

It is...

	A	B	C	D
2	Yes	Acai	Yes	TRUE
3	Noise	Aceola	Noise	TRUE
4	Yes	Apple	Yes	TRUE
5	Yep!	Mulberry	Yep!	TRUE
6	Ride	Blackberry	Ride	TRUE
7	Height	Apricots	Height	TRUE
8	Ok	Aceola	Noise	FALSE
9	No	Aceola	Noise	FALSE
10	Eat	Blueberries	Eat	TRUE
11	Fun	Blueberries	Eat	FALSE
12	Ocean	Durian	Ocean	TRUE
13	Yes	Goji berries	Yes	TRUE
14	Island	Banana	Island	TRUE
15	Fruit	Grapefruit	Fruit	TRUE
16	Why	Gooseberry	Why	TRUE
17	Now	Durian	Ocean	FALSE
18	Okies	Melon	Okies	TRUE
19	Okiey	Melon	Okies	FALSE
20	Okies	Melon	Okies	TRUE

col A is you answers, col C is my answers, col D is differences

The differences are coming in because you have different nutrients for the same fruit. How would excel know which 1 you want returned?

[Phuocam]

Try...
=LOOKUP(2,1/(K:K=B2),L:L)

[FDibbins]

Phuocam, that leave many returns that do not match what the OP posted

[FlameRetired]

If I understand correctly try this array-entered formula in A2 and fill down.

=INDEX($L$2:$L$39,SMALL(IF($B2=$K$2:$K$39,ROW($K$2:$K$39)-MIN(ROW($K$2:$K$39))+1),COUNTIF($B$2:$B2,$B2)))

If you aren’t familiar with array-entered formulas array enter means the formula must be committed from edit mode by simultaneously pressing and holding down Ctrl and Shift while hitting Enter.

[bjnockle]

FlameRetired - works like a charm. Thanks for the solution

[FlameRetired]

You're welcome. Glad to help and thanks for the feedback.