Extract Text from the Text

[soniakhurana22]

I want to extract 600x12x1134 from the below line:-

Development Fee @ Rs.600/- p.m. for 1134 students (600x12x1134)


and then multiply these numbers and put in another cell:-

=RIGHT(B48,LEN(TRIM(B48))-FIND("(",B48))

My RESULT IS 600x12x1134)

Can you please correct me in formula????

[zbor]

Based on your solution:

=SUBSTITUTE(RIGHT(B48,LEN(TRIM(B48))-FIND("(",B48)), ")", "")

[shukla.ankur281190]

Or Try

=REPLACE(RIGHT(B48,LEN(TRIM(B48))-FIND("(",B48)),FIND(")",RIGHT(B48,LEN(TRIM(B48))-FIND("(",B48))),1,"")

=REPLACE(RIGHT(B48,LEN(TRIM(B48))-FIND("(",B48)),FIND(")",RIGHT(B48,LEN(TRIM(B48))-FIND("(",B48))),1,"")

[Beamernsw]

You said you wanted to multiply those numbers. If so, then you'll need to separate them.
Try these:-
C48: =--MID(B48,FIND("(",B48)+1,FIND("x",B48)-FIND("(",B48)-1)
D48: =--MID(B48,FIND("x",B48)+1,FIND("x",B48,FIND("x",B48)+1)-FIND("x",B48)-1)
E48: =--MID(B48,FIND("x",B48,FIND("x",B48)+1)+1,LEN(B48)-FIND("x",B48,FIND("x",B48)+1)-1)

[soniakhurana22]

Thanks all of you its working now using substitute : -
=SUBSTITUTE(RIGHT(A1,LEN(TRIM(A1))-FIND("(",A1)),")","")

But now if space is there at the end

Development Fee @ Rs.600/- p.m. for 1134 students (6100x112x11139)
in this case my result is 100x112x11139)

[zbor]

Here, for all solutions.

=SUBSTITUTE(SUBSTITUTE(RIGHT(SUBSTITUTE(A1,"(",REPT(" ",255)),255),")","")," ","")

It will work also if you have more brackets in the text like:
Development Fee @ (Rs.600/)- p.m. for 1134 students*(6100x112x11139)*

[soniakhurana22]

THANKS zbor ur formula is working in all the cases....but it goes beyond my reach...

ONE HURDLE IS SOLVED....
Second hurdle:-
I want to split these numbers using x sign , MULTIPLY THESE NUMBERS and put the result in another cell....Is that possible using the formula or I have to used the module???

[AlKey]

Here is another way

to get string from the parenthesis:

=TRIM(MID(SUBSTITUTE(SUBSTITUTE(B48,")","("),"(",REPT(" ",99)),99,99))

To multiply the results

use this array formula

=PRODUCT(IFERROR(--TRIM(MID(SUBSTITUTE(C48,"x",REPT(" ",30)),30*(COLUMN($A:$Z)-1)+1,30)),""))

***Array formula must be entered by using key combination of CTRL+SHIFT+ENTER and not just ENTER

	B	C	D
47	Text	From the parenthesis	Multiplied results
48	Development Fee @ Rs.600/- p.m. for 1134 students (600x12x1134)	600x12x1134	8164800
49	Development Fee @ Rs.600/- p.m. for 1134 students* (6100x112x11139)*	6100x112x11139	7610164800

Sheet: Sheet1

[soniakhurana22]

Thanks all of you EXCEL EXPERTS....

I just want to ask one simple Question...Array formula is working correctly...I am applying this same array formula on locked file....MESSAGE IS coming when Pressing CTRL+SHIFT+ENTER..The specified formula cannot be entered because it used more levels of nesting that are allowed in the current file format.

What is the reason on locked file , why this array formula cannot be applied??

[JohnTopley]

There is no need to highlight any of your thread: we are quite capable of reading normal text.

[sarvagya]

Save as Excel Workbook.

[soniakhurana22]

Its done....I click on File Menu--Save as-->Save the file as Excel Workbook(Default Format).Now I am able to apply the array formula.

Lots of thanks to all who helped me in solving my query.