Delete all characters after last numeric

[makinmomb]

This have on a1

CL712BG
CL712BG
CL712BG
CL712BG
CL712BG
CL712BR
CL712BR
CL712BR
CL712BR
CL712BR

Want

CL712
CL712
CL712
CL712
CL712
CL712
CL712
CL712
CL712
CL712

[Jonmo1]

Is that a consistent format?

You could just do
=LEFT(A1,5)

[makinmomb]

This may not work as character could not be same

[canapone]

Hi All,

a possible formula:

=LEFT(A1,MAX(INDEX(ISNUMBER(--MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))*ROW(INDIRECT("1:"&LEN(A1))),0)))

Hope it helps

[Jonmo1]

Can you give a more complete sample set of data, that shows all possible formats?

[samba_ravi]

=iferror(left(a1,lookup(2,1/(mid(a1,row(indirect("1:"&len(a1))),1)),row(indirect("1:"&len(a1))))),a1)

Please Login or Register  to view this content.

[Tony Valko]

Assumes every cell will contain a single string of digits.

=LEFT(A1,LOOKUP(10,--MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1),ROW(INDIRECT("1:"&LEN(A1)))))

[bebo021999]

In general, (for any cases with mixture of values and strings, i think)

=LEFT(A1,LEN(A1)+1-MATCH(TRUE,ISNUMBER(--MID(A1,LEN(A1)-ROW(INDIRECT("1:"&LEN(A1)))+1,1)),0))

...confirmed by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. You will know the array is active when you see curly braces { } appear around your formula. If you do not CTRL+SHIFT+ENTER you will get an error or a clearly incorrect answer. Press F2 on that cell and try again.