Vlookup for a formula result

[JTemple]

I am not even sure if I have the right formula. I am trying to have a cell auto filled based on the value of a cell found with the Vlookup formula. On the attached sample, if the cell value in column D on the players sheet is = w next to the player listed in cell g5 on the bracket sheet, cell F7 should auto fill to the g5 value. If the value = L, the F7 cell should auto fill to the g9 value.
My goal is when the result of each match is entered on the player list with a W or L, the correct player is auto filled on the bracket sheet.

[Glenn Kennedy]

Maybe this is what you want:

=IF(VLOOKUP(G5,Players!B:C,2,FALSE)="w",G5,G9)

[JTemple]

Glenn,
Thank you your response. This does not work but I erred in mentioning a factor. On the players list for the highlighted cell, it should look for the value in the appropriate round column. In this sample, the round 4 auto fill should be determined by the round 2 result (W or L) in the players sheet.

[Fluff13]

How about

Please Login or Register  to view this content.

[Glenn Kennedy]

???G5:

=IF(INDEX(Players!C:M,MATCH(Bracket!H4,Players!B:B,0),MATCH(Bracket!H$2,Players!$C$1:$M$1,0))="w",H4,H6)

If not, please remove the formulae and add some manually calculated results in SHADED cells so we can see where we are meant to be looking.

[Gregb11]

In G5 you can use this formula:

=IFERROR(FILTER(Players!$B$2:$B$17,(FILTER(Players!$C$2:$M$17,H$2=Players!$C$1:$M$1)="l")*((Players!$B$2:$B$17=H4)+(Players!$B$2:$B$17=H6))),"")

This can be copied to all Round 2 entries (G9, G13, G17, etc.)

For round 4 (cell F7) you can use this formula:
=IFERROR(FILTER(Players!$B$2:$B$17,(FILTER(Players!$C$2:$M$17,G$2=Players!$C$1:$M$1)="w")*((Players!$B$2:$B$17=G5)+(Players!$B$2:$B$17=G9))),"")
This can be copied to F15, F23, and F31. the same formula can also be copied to Round 6(cells E9, E17, E25, and E33)

For Round 7 (D13), use:
=IFERROR(FILTER(Players!$B$2:$B$17,(FILTER(Players!$C$2:$M$17,E$2=Players!$C$1:$M$1)="w")*((Players!$B$2:$B$17=E9)+(Players!$B$2:$B$17=E17))),"")
copy to D29. This same formula can be copied to Round 9 (cells C17 and C33)

Winner of the loser bracket formula:
=IFERROR(FILTER(Players!$B$2:$B$17,(FILTER(Players!$C$2:$M$17,B$2=Players!$C$1:$M$1)="w")*((Players!$B$2:$B$17=B25)+(Players!$B$2:$B$17=B37))),"")

See Attached

[JTemple]

Thank you. This appears to have solved my issue.

[Fluff13]

Not sure which post you are referring to, but glad to help & thanks for the feedback.