Find Minimum Number From same number range.

[sanju2323]

I have the same number series need to find the smallest number.

[MarvinP]

Hi sanju,

This takes an array formula where you press Control+Shift+Enter to confirm the equation.

[azumi]

In C3

=MIN(IF($A$3:$A$66=$A3,$B$3:$B$66))

and press CTRL+SHIFT+ENTER button together (array formula style), and then copied down

[sanju2323]

Thanks for your quick replay, But use large format array, it is slow. Is possible without the use of the array.

[azumi]

Try this non array solution:

put on C3 and copied down

=SUMPRODUCT(MIN(($A$3:$A$66=$A3)*$C$3:$C$66+9,99E+307*($A$3:$A$66<>$A3)))

[sanju2323]

azumi, It does not work, Have you used the formula

[samba_ravi]

C3=MIN(INDEX(($A$3:$A$66<>A3)*25^25+$B$3:$B$66,0))
Try this copy towards down

[azumi]

Ooops sorry change to:

=SUMPRODUCT(MIN(($A$3:$A$66=$A3)*$B$3:$B$66+9,99E+307*($A$3:$A$66<>$A3)))

[samba_ravi]

modification to @ Azumi
=SUMPRODUCT(MIN($B$3:$B$66+9.99E+307*($A$3:$A$66<>$A3)))
or
=SUMPRODUCT(MIN($B$3:$B$66+9,99E+307*($A$3:$A$66<>$A3)))

[sanju2323]

Thank you very much to all those who reply Especially, azumi & nflsales
This Time Is Perfectly Work.