How to extract multiple words from one cell

I am trying to search a single Cell and extract different words to summarize issues.

I am extracting ticket data which includes Short Desc, Desc and resolution. I have concatenated those 3 fields into one field(one cell which is D2)
I want to search cell D2 and extract different words which can allow me to quickly categorize issues.

In cell A2 i have entered the following formula:

=IF($D2="","",
IF(ISNUMBER(SEARCH("missing",$D2)),"Missing",
IF(ISNUMBER(SEARCH("new",$D2)),"new",
IF(ISNUMBER(SEARCH("*upgrade*",$D2)),"upgraded",
IF(ISNUMBER(SEARCH("*error*",$D2)),"error",
" ")))))

It works but only returns the first value found. Is there a way to return ALL matches found? See attachedBook1.xlsx

Hi Katie and welcome to the forum,

Something like this perhaps? First two works only looked for in this formula.

=CONCATENATE(IF(ISNUMBER(SEARCH("missing",$D2)),"Missing",""),IF(ISNUMBER(SEARCH("New",$D2))," New",""))

Split the IFs ... don't nest them ... and concatenate the results, perhaps separated by a space.

Formula:

=IF($D2="","",TRIM(

IF(ISNUMBER(SEARCH("missing",$D2)),"Missing ","") &

IF(ISNUMBER(SEARCH("new",$D2)),"new ","") &

IF(ISNUMBER(SEARCH("*upgrade*",$D2)),"upgraded ","") &

IF(ISNUMBER(SEARCH("*error*",$D2)),"error ","")   ))

Regards, TMS

You're welcome.



If you are satisfied with the solution(s) provided, please mark your thread as Solved.


New quick method:
Select Thread Tools-> Mark thread as Solved. To undo, select Thread Tools-> Mark thread as Unsolved.

Or you can use this way:

How to mark a thread Solved
Go to the first post
Click edit
Click Go Advanced
Just below the word Title you will see a dropdown with the word No prefix.
Change to Solved
Click Save


You may also want to consider thanking those people who helped you by clicking on the little star at the bottom left of their reply to your question.