Generate information through one click... "LOOKUP"

Hello all...
i have been searching and trying to figure out something but i cant help myself.
I have thousands of data and i need to select the one of the product and it should display the entire information on that product automatically.
I tried Vlookup, but it proved useless for my this problem... i am new to excel, learning, dont know much functions but i am desperate to solve my problems..
I have attached the file, please download it and give me a solution for it...

Put this formula in H2 of Sheet1:

=IF(A2="","-",A2&"_"&COUNTIF(A$2:A2,A2))

then copy down to the bottom of your data, or beyond to allow for new data to be added.

Then put this formula in A7 of the Display sheet:

=IFERROR(MATCH(D$3&"_"&ROWS($1:1),Sheet1!H:H,0),"-")

and this one in B7:

=IF(OR($A7="-",$A7=""),"",INDEX(Sheet1!B:B,$A7))

Copy this formula across to G7, then apply a date format to D7 and a number format to E7, and then copy all the formulae from A7~;G7 down as far as you need them. If you put this formula in E3:

=COUNTIF(Sheet1!A:A,D3)

it will tell you how many records to expect for the Product you have chosen in D3.

Hope this helps.

Pete

Thanks for the rep.

The first formula adds a unique sequential number onto the end of the product name. The second formula recreates those sequential numbers (through the ROWS($1:1) term as it is copied down) along with the product name chosen in D3, and looks to see if there is a match in column H of Sheet1 - if there is, it will return the row number where the match occurs. The third formula returns the corresponding data from column B of Sheet1, but when it is copied across it will get the data from column C, then column D, and so on.

Hope this helps.

Pete