Help require to modify this array formula

Dear friends,
I want to find out the first topper student in each subject. The formula is working fine if there are not same marks in subjects but if the two or more students secure same marks then it is not giving correct output. It’s taking the first student in series which I don’t want.

The condition is:
If two or more students secure same marks then the rank should be taken in the consideration. The top rank should be given first number though it’s not first in the series based on roll no in the result sheet.

In this case the topper student in Marathi and Hindi is wrong output by the formula. I have given the correct required output table in the file.

Please suggest me a modification in the formula.

Any help will be appreciated.

Thanking you,

Please add in your question this is a related question to the questions below.

http://www.excelforum.com/excel-form...ml#post3811529

Using your posted workbook...
This ARRAY FORMULA, completed by holding down CTRL and SHIFT when you press ENTER (instead of just pressing ENTER) begin the list of top students

J5: =IFERROR(INDEX(Test!$E$6:$E$90,MATCH(MIN(IF(((Test!$F$4:$M$4=I5)*Test!$F$6:$M$90)=MAX(((Test!$F$4:$M$4=I5)
*(Test!$F$6:$M$90))),Test!$R$6:$R$90)),Test!$R$6:$R$90,0)),"")

and this regular formula returns the corresponding marks

K5: =IFERROR(LARGE(INDEX(Test!$F$6:$M$90,0,MATCH(Summary!$I5,Test!$F$4:$M$4,0)),$H5),"")

Copy both formulas down as far as you need.

Is that something you can work with?

Hi Ron,
Thank you. It's absolutely working fine in English version but not in my devanagari version. Please see the file and suggest me a correction.

Thank you.

Try this.....
In K5

=IFERROR(LARGE(INDEX(Test!$F$6:$M$90,0,MATCH(Summary!$I5,Test!$F$4:$M$4,0)),$H$5),"")

and copy down.

In J5 (Array Formula)

=INDEX(Test!$E$6:$E$90,SMALL(IF(Test!$R$6:$R$90=MIN(IF(INDEX(Test!$F$6:$M$90,0,MATCH(Summary!$I5,Test!$F$4:$M$4,0))=K5,Test!$R$6:$R$90)),ROW(Test!$E$6:$E$90)-ROW(Test!$E$6)+1),1))

and copy down.

Is this what you are trying to achieve?

Hi Sktneer,
Excellent! It's working absolutely fine as per my requirement.

By heart I appreciate you for your kind cooperation to solve my problem.

Thank you and have a nice day.

You're welcome. Thanks for the feedback.