Help needed, not(isblank)

[PalcicAlbert]

Hello,

I need help. for example, in cell D1 I want excell to automatically enter some text based on which cell A1, B1 or C1 I filled.

More details:if a put something (no matter what) in:
- cell A1, value in the cell D1 needs to be 'car'
- cell B1, value of the D1 would be 'house'
- cell C1, value od the D1 would be 'road'.

I asume the correct function should be not(isblank) but I don't know how to use it

thanks in advance.

--
palcic-albert

[nathansav]

if a1<>"" ,true, false

[boopathiraja]

tRY
=IF(COUNTA(A1),"CAR",IF(COUNTA(B1),"HOUSE",IF(COUNTA(C1),"ROAD")))

[sktneer]

Try this......

In D1

=IF(A1<>"","Car",IF(B1<>"","House",IF(C1<>"","Road","")))

OR

=IFERROR(INDEX({"Car","House","Road"},MATCH(TRUE,INDEX(A1:C1<>"",0),0)),"")

[Jonmo1]

Will there only be one cell with data in A1:C1 ?
What type of data would be in the cell, Text or Number. Or could be either?

[Olly]

Try entering this in D1, as an array formula (Ctrl-Shift-Enter)

=CHOOSE(MATCH(FALSE,ISBLANK(A1:C1),0),"car","house","road")

[AlKey]

Or this

=IFERROR(INDEX({"Car","House","Road"},SMALL(IF(A1:C1<>"",COLUMN(A1:C1)),1)),"")

...confirmed by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. You will know the array is active when you see curly braces { } appear around your formula. If you do not CTRL+SHIFT+ENTER you will get an error or a clearly incorrect answer. Press F2 on that cell and try again.

[FDibbins]

Hi, welcome to the forum

Assuming you are testing for either cell is blank or cell has contents, and that only 1 of the 3 will have contents, here is an alternative...

=IF(A1="","CAR",IF(B1="","HOUSE",IF(C1"","ROAD")))

If 1 of the 3 will always have contents, you can shorten that to...
=IF(A1="","CAR",IF(B1="","HOUSE","ROAD"))

[PalcicAlbert]

Hi,

thanks to all for help, but (I don't know what the problem is) every formula I copy/paste return an error (with just enter or ctrl-shift-enter). for example, on the last one from FDibbins, excell select this:
,"CAR",IF

Or in the formula:
=IFERROR(INDEX({"Car","House","Road"},SMALL(IF(A1:C1<>"",COLUMN(A1:C1)),1)),"")

bold are:
"Car","House","Road".

maybe some option setting is wrong?

[sktneer]

May be you should use ; (semicolon) instead of , (comma) in the formulas. See if this helps.

[PalcicAlbert]

that helps, _I replace all , with ;

thanks everyone!

--
p-a