Nested IF Function

you can use a nested IF

IF (Population<6955) PopScore=0.
IF (Population>=6955 & Population <13911) PopScore=5.
IF (Population>=13911 & Population <20866) PopScore=10.
IF (Population>=20866 & Population <=34777) PopScore=15.
IF (Population>34777 & Population <=41733) PopScore=10.
IF (Population>41733 & Population <=48688) PopScore=5.
IF (Population>48688) PopScore=0.

need to have a cell for
Population Cell = A2
Popscore Cell =B2
so assume those

You would probably be better of with a lookup BUT as an IF
in B2 put
=IF(A2<6955,0,IF(AND(A2>=6955,A2<13911),5,IF(AND(A2>=13911,A2<20866),10,IF(AND(A2>=20866,A2<=34777),15,IF(AND(A2>34777,A2<=41733),10,IF(AND(A2>41733,A2<=48688),5,IF(A2>48688,0,"out of Range")))))))

I would perhaps change to

=IF(OR(A2<6955,A2>48688),0,IF(AND(A2>=6955,A2<13911),5,IF(AND(A2>=13911,A2<20866),10,IF(AND(A2>=20866,A2<=34777),15,IF(AND(A2>34777,A2<=41733),10,IF(AND(A2>41733,A2<=48688),5,"out of Range"))))))

And can probably simplify further
=IF(OR(A2<6955,A2>48688),0,IF(A2<13911,5,IF(A2<20866,10,IF(A2<=34777,15,IF(A2<=41733,10,IF(A2<=48688,5,"out of Range"))))))

Just to show you the logic as I progressed , so you can then perhaps apply to other SPSS requirements

You could also use a lookup table or array

Or maybe this:

Create a table:

	D	E
1	Lookup Table
2	0	0
3	6955	5
4	13911	10
5	20866	15
6	34777	10
7	41733	5
8	48688	0

Then use formula
=VLOOKUP(A2,$D$2:$E$8,2,1)

	A	B	C	D	E
1	Population	Score		Lookup Table
2	6500	0		0	0
3	6955	5		6955	5
4	13911	10		13911	10
5	20866	15		20866	15
6	34776	15		34777	10
7	41733	5		41733	5
8	48688	0		48688	0
9	34777	10
10	48688	0
11	50000	0

Based on your last post it seems that you are satisfied with the solution(s) you've received but you haven't marked your thread as SOLVED. If your problem has not been solved you can use Thread Tools (located above your first post) and choose "Mark this thread as unsolved".
Thanks.

Also, as a relatively new member of the forum, you may not be aware that you can thank those who have helped you by clicking the small star icon located in the lower left corner of the post in which the help was given. By doing so you can add to the reputation(s) of those who helped.