help: need spreadsheet that you specify number of teams in group then displays win loss

The following uses a formula to create a binary number with the number of digits equal to the number of team pairs, then creates W/L blocks for each possibility.

Option Explicit
Dim rngPrs As Range, rngNum As Range, rngBin As Range
Dim Pairs As Long, Col As Long, Rw As Long, Cnt As Long, BlkCnt As Long

Sub CreateWLBlocks()
    Set rngPrs = Range("A1") ' Adjust to cell containing the # of teams
    Set rngNum = Range("B1") ' Adjust to any available cell
    Set rngBin = Range("C1") ' Adjust to any available cell

    Pairs = rngPrs.Value
    rngNum.Value = 0
    rngBin.Formula = "=DEC2BIN(" & rngNum.Address & "," & rngPrs.Address & ")"

    Sheets.Add after:=Sheets(Sheets.Count)
    Col = 1
    Rw = 1
    BlkCnt = 1
    Do Until IsError(rngBin.Value)
        Call CreateBlock
        BlkCnt = BlkCnt + 1
        If BlkCnt > Pairs Then
            With Range(Cells(1, Col), Cells(1, Col + 1))
                .EntireColumn.HorizontalAlignment = xlCenter
                .ColumnWidth = 7
            End With
            BlkCnt = 1
            Rw = 1
            Col = Col + 2
        End If
        rngNum.Value = rngNum.Value + 1
    Loop
    With Range(Cells(1, Col), Cells(1, Col + 1))
        .EntireColumn.HorizontalAlignment = xlCenter
        .ColumnWidth = 7
    End With

    rngNum.ClearContents
    rngBin.ClearContents
End Sub

Sub CreateBlock()
    With Range(Cells(Rw, Col), Cells(Rw + Pairs - 1, Col + 1))
        With .Borders(xlEdgeLeft)
            .LineStyle = xlContinuous
            .Weight = xlThin
        End With
        With .Borders(xlEdgeTop)
            .LineStyle = xlContinuous
            .Weight = xlThin
        End With
        With .Borders(xlEdgeBottom)
            .LineStyle = xlContinuous
            .Weight = xlThin
        End With
        With .Borders(xlEdgeRight)
            .LineStyle = xlContinuous
            .Weight = xlThin
        End With
    End With

    For Cnt = 1 To Pairs
        If Mid(rngBin.Value, Cnt, 1) = "0" Then
            Cells(Rw, Col).Value = "W"
            Cells(Rw, Col + 1).Value = "L"
        Else
            Cells(Rw, Col).Value = "L"
            Cells(Rw, Col + 1).Value = "W"
        End If
        Rw = Rw + 1
    Next
End Sub

It works for me in the attached. Just open it and run the CreateWLBlocks subroutine.
TeamPairs.xlsm

Sorry -- thought I had pointed that out in the code comments. Glad you figured it out.