SumIF, using a formula as the range

Not sure best way to describe this. I want to do a SumIF, but instead of a range I want a formula, for example...

A B C
1 5 5
2 2 9
3 8 9
4 1 8

Is it possible to do a SumIF where I sum the values of C only if (B-A) > 3, or something along those lines.
The way I've been doing it is by creating an extra column and then putting column D in the range argument, but I was wondering if there was a simpler way to do it. Something like [b:b-a:a] as the range, but not sure if that's possible.

Thanks

There is also a SUMPRODUCT solution that does not require Ctrl+Shift+Enter:

=SUMPRODUCT(--((B2:B5-A2:A5)<3),C2:C5)

Thank you both, both worked perfectly. Trying to do 1 more thing a little more complex - thought I would be able to use these formulas and adapt it but not working. Worked for the 1st part of the spreadsheet but not the second....

The spreadsheet has data like this:
[xxxxx] DATA
[xxx] DATA
[xxxxxxxx] DATA

I want to have the range be a formula for the amount of numbers between the [ and the ]

I've been using =FIND("[",A1)-FIND("]",A1) and just dragging that down to create a new cell, then using those cells as the range. Is there a way to incorporate that into the sumif?

I'm not sure I understand what you want as the conditional expression. By "amount of numbers between the [ and the ]", do you mean the value between the square brackets or do you mean the number of digits between the brackets?

Could you restate your problem as "If this equals that, then sum these cells."

The amount of digits, restated:

If (Find("[",A) - Find("]",A)) > 5, then Sum ColumnB

=SUMPRODUCT(--(LEN(A:A)>7),B:B)

or

Ctrl+Shift+Enter
=SUM(IF(LEN(A:A)>7,B:B))

Almost got it. I wasn't clear in my previous post, the data looks like
[xxxx] DATA <--- That's just one cell, then the numbers to be summed are in the next column. I modified the formula to almost work...

=SUMPRODUCT(--((FIND("]",A:A)-FIND("[",A:A))=5),B:B)
For some reason this is giving me #VALUE as the answer. When I put it for a smaller range, like only A1:A7 then it works. But if there's a blank line in that range, it goes back to #VALUE. Not sure what I'm doing wrong.

The error in the formula is occuring because FIND returns an error on a blank cell. You can fix this with an IF or an IFERROR, however the SUMPRODUCT formula becomes an array formula and requires CSE.

Ctrl+Shift+Enter
=SUMPRODUCT(--(IFERROR(FIND("]",A:A)-FIND("[",A:A)=5,0)),B:B)

This array formula has a noticeable calculation delay when I test. This can be reduced by using cell ranges rather than whole columns, say A1:A10000 and B1:B10000.

If you don't require a check for "[", calculation time can also be improved by doing just one FIND per cell.
IFERROR(FIND("]",A1:A10000)=6,0)