How to count occurrences of a comparison within an array

I have two columns of dates that look something like this:

(Column A	(Column B)
Order Received	Order Processed
02/14/2014	02/14/2014
02/15/2014	02/25/2014
n/a
02/16/2014	canceled
02/16/2014	02/17/2014
n/a	n/a
02/17/2014	02/28/2014

I'm looking for a formula that will tell me how many times the date in the first column is 5 days or less than the date in the second column. In other words, count how many times column B minus column A is less than or equal to five for the array (i.e. B-A<=5).

I have tried several formulas without success, usually because the cells with text in them throw the formula(s) off.

Here are some examples of formulas that didn't work:

=SUMPRODUCT(--ISNUMBER('2014'!$E$2:$E$1001),--ISNUMBER('2014'!$F$2:$F$1001),--('2014'!$F$2:$F$1001-'2014'!$E$2:$E$1001<=5))

{=COUNTIF('2014'!$F$2:$F$1001,('2014'!$F$2:$F1001)-('2014'!$E$2:$E$1001)<=5)}

=SUMPRODUCT(--(N('2014'!$F$2:$F$1001)-N('2014'!$E$2:$E$1001)<=5))

{=IF(ISNUMBER('2014'!$F:$F),IF(ISNUMBER('2014'!$E:$E),SUMPRODUCT(--('2014'!$F:$F-'2014'!$E:$E<=5))))}

See if this will work for you...
=COUNTIF($B$2:$B$9,">'"&A2-5)

Try this...

Data Range

	A	B	C	D
1	Order Received	Order Processed	------	Count
2	2/14/2014	2/14/2014		2
3	2/15/2014	2/25/2014
4	n/a
5	2/16/2014	canceled
6	2/16/2014	2/17/2014
7
8	n/a	n/a
9	2/17/2014	2/28/2014

This array formula** entered in D2:

=SUM(IF(IF(ISNUMBER(B2:B9),B2:B9,100000)-IF(ISNUMBER(A2:A9),A2:A9,1)<=5,1))

** array formulas need to be entered using the key
combination of CTRL,SHIFT,ENTER (not just ENTER).
Hold down both the CTRL key and the SHIFT key
then hit ENTER.

OK, I thought you wanted to copy that down to compare each row, sorry

If you're testing for a specific month, are all the dates within the same year?

OK, this is getting kind of gnarly. Hope it doesn't get any more complicated!

Data Range

	A	B	C	D
1	Order Received	Order Processed	------	Count
2	2/14/2014	2/14/2014		2
3	2/15/2014	2/25/2014
4	n/a
5	2/16/2014	canceled
6	2/16/2014	2/17/2014
7	1/12/2014	1/15/2014
8	n/a	n/a
9	2/17/2014	2/28/2014

This array formula entered in D2:

=SUM(IF(IF(ISNUMBER(B2:B9),IF(MONTH(B2:B9)=2,B2:B9,100000),100000)-IF(ISNUMBER(A2:A9),IF(MONTH(A2:A9)=2,A2:A9,1),1)<=5,1))

** array formulas need to be entered using the key
combination of CTRL,SHIFT,ENTER (not just ENTER).
Hold down both the CTRL key and the SHIFT key
then hit ENTER.