How can I use VBA to create multiple pie charts from a series of data

Hi

I need help creating multiple pie charts from a series of data, Basically there are 2 weekly totals that I need to make into a weekly pie chart, is there anyway I can do this without creating a chart for each individual week manually and having them produced automatically with a vba.

It would be a great help if anyone could help me.

Thanks

John

Maybe something like this...

Option Explicit

Sub test()

    Dim ChrtObj As ChartObject
    Dim MySeries As Series
    Dim LeftPos As Long
    Dim TopPos As Long
    Dim LastCol As Long
    Dim i As Long

    LeftPos = 50
    TopPos = 75

    LastCol = Cells(1, Columns.Count).End(xlToLeft).Column
    
    For i = 2 To LastCol
        Set ChrtObj = ActiveSheet.ChartObjects.Add(LeftPos, TopPos, 360, 215)
        With ChrtObj.Chart
            .ChartType = xlPie
            Set MySeries = .SeriesCollection.NewSeries
            With MySeries
                .XValues = Range(Cells(2, "a"), Cells(3, "a"))
                .Values = Range(Cells(2, i), Cells(3, i))
                .Name = Cells(1, i).Value
                .ApplyDataLabels Type:=xlDataLabelsShowValue
                .DataLabels.NumberFormat = "#,##0"
            End With
            LeftPos = .Parent.Left + .Parent.Width + 15
        End With
    Next i
    
End Sub

Sorry for the old thread revival (hope it's ok to do this?)

If the data is stored in rows rather than columns, how & where would the code above need to be changed?

Thanks in advance

Sorry, I'll start a new thread.