Hiding a ScrollBar

Hi all,

I am trying to fine tune a charting tool but Excel is acting odd, or I am odd, or both . Whatever the case may be, if you fill the charts with data using the buttons, click the top chart to zoom the view size, use the scroll bar, and then click the top chart again to zoom the view size back to 75, the scroll bar will not hide (unless you click the chart again, and then again).
Within the module ChartClick, I have the following code:

Dim scrBar1 As Shape, scrBar2 As Shape
Set scrBar1 = ActiveSheet.Shapes("ScrollBar1")
Set scrBar2 = ActiveSheet.Shapes("ScrollBar2")
'---The first if statement expands the view size---'
    If ActiveWindow.Zoom = 75 And ActiveWindow.Zoom < 100 Then
        Application.DisplayFullScreen = True
        ActiveWindow.Zoom = 100
        Application.Goto Sheets("Sheet2").Range("A3"), True
        HideCansim
        scrBar1.Visible = msoFalse
        scrBar2.Visible = msoTrue
        RadioButton_Explode
        Help_Explode
        With Range("M12:M16")
            .Font.ColorIndex = 0
            .Font.Size = 14
        End With
        Range("G12").Select
        Exit Sub
    End If
'---The next if statement zoom the viewsize back to 75---'
    If ActiveWindow.Zoom = 100 Then
        Application.DisplayFullScreen = False
        ActiveWindow.Zoom = 75
        Application.Goto Sheets("Sheet2").Range("A1"), True
        UnHideCansim
        scrBar1.Visible = msoTrue
        scrBar2.Visible = msoFalse
        RadioButton_Implode
        Help_Implode
        Range("M12:M16").Font.ColorIndex = 2
        Range("G12").Select
        Exit Sub
    End If

Does something here look off? Perhaps, while I am thinking about it, is it a sequential code reading issue? I don't know but if someone has an idea, I would love to here it! Thanks so much

Well, its has nothing to do with sequential code reading.

Try adding a DoEvents line after chaning the visible properties of the scrollbars.

        HideCansim
        scrBar1.Visible = msoFalse
        scrBar2.Visible = msoTrue
DoEvents
        RadioButton_Explode

Thanks Andy, but no changes.

My bad, I did not actually use the scroller to adjust the chart before zooming out. When I did I could replicate the problem.

Try this instead.

Sub Chart1_Click()
    
    Application.ScreenUpdating = False
    Dim scrBar1 As Shape, scrBar2 As Shape
    
    Set scrBar1 = ActiveSheet.Shapes("ScrollBar1")
    Set scrBar2 = ActiveSheet.Shapes("ScrollBar2")
    If ActiveWindow.Zoom = 75 And ActiveWindow.Zoom < 100 Then
        Application.Goto Sheets("Sheet2").Range("A3"), True
        
        Application.DisplayFullScreen = True
        ActiveWindow.Zoom = 100
        HideCansim
        scrBar1.OLEFormat.Object.Visible = False
        scrBar2.OLEFormat.Object.Visible = True
        RadioButton_Explode
        Help_Explode
        With Range("M12:M16")
            .Font.ColorIndex = 0
            .Font.Size = 14
        End With
        Range("G12").Select
        Application.ScreenUpdating = True
        Exit Sub
    End If
    If ActiveWindow.Zoom = 100 Then
        
        Application.Goto Sheets("Sheet2").Range("A1"), True
        Application.DisplayFullScreen = False
        ActiveWindow.Zoom = 75
        UnHideCansim
        scrBar1.OLEFormat.Object.Visible = True
        scrBar2.OLEFormat.Object.Visible = False
        RadioButton_Implode
        Help_Implode
        Range("M12:M16").Font.ColorIndex = 2
        Range("G12").Select
        Application.ScreenUpdating = True
        Exit Sub
    End If
    
End Sub

I cannot express how much I appreciate your help with this, off and on throughout the creation of this charting tool. Your suggestion worked perfectly. Thanks again.