Deactivate chart created with VBA

I've programmically created a chart on the fly in Excel 2007. I'm running into an issue with the chart "deselecting" after being created. If I step through my code it all works with no issue, however if I let it run on its own the range selection at the end does not actually happen. Any ideas?

Sub FormatChart_Coverage(strChart As String)

Dim srs As series

    ThisWorkbook.Sheets("Report").ChartObjects(strChart).Activate
    
        ActiveChart.SetElement (msoElementLegendNone) ''Hide the legend
        ActiveChart.SetElement (msoElementDataTableWithLegendKeys) ''Show the data table
    
    For Each srs In ActiveChart.SeriesCollection
    
        If srs.Name = "Total" Then
            srs.AxisGroup = 2
            srs.Select
            With Selection.Border
                .Weight = xlThin
                .LineStyle = xlNone
            End With
            Selection.Interior.ColorIndex = xlNone

        ElseIf srs.Name = "YTD Goal" Then
            srs.ChartType = xlLineMarkers
            srs.Select
            With Selection
                .MarkerStyle = -4115
                .MarkerSize = 13
                .MarkerBackgroundColorIndex = 3
                .MarkerForegroundColorIndex = 3
            End With
            With Selection.Border
                .LineStyle = xlNone
            End With
        End If
    Next
    
     ActiveChart.DataTable.Select
        Selection.Font.Size = 8
    
    ActiveChart.Axes(xlValue, xlSecondary).Select
        Selection.MajorTickMark = xlNone
        Selection.TickLabelPosition = xlNone

    ThisWorkbook.Sheets("Report").ChartObjects(strChart).Select
        Selection.OnAction = "'" & ThisWorkbook.Name & "'!Drill_CoverageForm"
        
    ActiveChart.Deselect
    
    ActiveSheet.Range("A1").Select

End Sub

You shouldn't need to select it in the first place:

Sub FormatChart_Coverage(strChart As String)
    Dim cht As Chart
    Dim srs As Series
    
    Set cht = ThisWorkbook.Sheets("Report").ChartObjects(strChart).Chart
    With cht
        .SetElement (msoElementLegendNone) ''Hide the legend
        .SetElement (msoElementDataTableWithLegendKeys) ''Show the data table
    
        For Each srs In .SeriesCollection
        
            If srs.Name = "Total" Then
                srs.AxisGroup = 2
                With srs.Border
                    .Weight = xlThin
                    .LineStyle = xlNone
                End With
                srs.Interior.ColorIndex = xlNone
                
            ElseIf srs.Name = "YTD Goal" Then
                srs.ChartType = xlLineMarkers
                With srs
                    .MarkerStyle = -4115
                    .MarkerSize = 13
                    .MarkerBackgroundColorIndex = 3
                    .MarkerForegroundColorIndex = 3
                End With
                srs.Border.LineStyle = xlNone
            End If
        Next srs
    
        .DataTable.Font.Size = 8
    
        With .Axes(xlValue, xlSecondary)
            .MajorTickMark = xlNone
            .TickLabelPosition = xlNone
        End With
    End With
    
    ThisWorkbook.Sheets("Report").ChartObjects(strChart).OnAction = "'" & ThisWorkbook.Name & "'!Drill_CoverageForm"

End Sub

I was able to assign the action without selecting the chart, however I do have to have the chart active in order to change the series properties. After which the chart does not deactivate, unless I step through the code line by line.

Updated code:

Sub FormatChart_Coverage(strChart As String)

Dim srs As series

    ThisWorkbook.Sheets("Report").ChartObjects(strChart).Activate
    
        ActiveChart.SetElement (msoElementLegendNone) ''Hide the legend
        ActiveChart.SetElement (msoElementDataTableWithLegendKeys) ''Show the data table
    
    For Each srs In ActiveChart.SeriesCollection
    
        If srs.Name = "Total" Then
            srs.AxisGroup = 2
            srs.Select
            With Selection.Border
                .Weight = xlThin
                .LineStyle = xlNone
            End With
            Selection.Interior.ColorIndex = xlNone

        ElseIf srs.Name = "YTD Goal" Then
            srs.ChartType = xlLineMarkers
            srs.Select
            With Selection
                .MarkerStyle = -4115
                .MarkerSize = 13
                .MarkerBackgroundColorIndex = 3
                .MarkerForegroundColorIndex = 3
            End With
            With Selection.Border
                .LineStyle = xlNone
            End With
        End If
    Next
          
    ActiveChart.DataTable.Font.Size = 8
    
    ActiveChart.Axes(xlValue, xlSecondary).MajorTickMark = xlNone
    ActiveChart.Axes(xlValue, xlSecondary).TickLabelPosition = xlNone

    ThisWorkbook.Sheets("Report").ChartObjects(strChart).OnAction = "'" & ThisWorkbook.Name & "'!Drill_CoverageForm"
         
    ThisWorkbook.Sheets("Report").Activate
    ActiveSheet.Range("A1").Select

End Sub

Originally Posted by kcaprik

I was able to assign the action without selecting the chart, however I do have to have the chart active in order to change the series properties.

why? Did you try my code at all?

Also, can you please put code tags round your code, per the forum rules?

you type:
[code]your code here[/code]

I don't see how you could have the same issue with my code since it does not select the chart at any point.

kcaprik, please take a moment to look at the forum rules and then edit your posts to add code tags.

Your post does not comply with Rule 3 of our Forum RULES. Use code tags around code. Posting code without them makes your code hard to read and difficult to be copied for testing. Highlight your code and click the # at the top of your post window. For more information about these and other tags, found here

I'm not sure what you are running, because I've tested it and it does not activate the chart and nor would I expect it to. Can you post the exact code you are using from start to finish?